Revison bump. Switch to EAPI 5. Reorder deps and configure switches. Other minor changes. Ebuild support for bug #452460. Build with libcdio-paranoia still needs a patch to work.

(Portage version: 2.1.11.31/cvs/Linux i686, signed Manifest commit with key 215AD14D)

3 files changed, 133 insertions, 5 deletions

diff --git a/media-sound/aqualung/ChangeLog b/media-sound/aqualung/ChangeLog
index b1af6f2f4678..3022d8ebeb3a 100644
--- a/media-sound/aqualung/ChangeLog
+++ b/media-sound/aqualung/ChangeLog
@@ -1,6 +1,20 @@
 # ChangeLog for media-sound/aqualung
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/ChangeLog,v 1.25 2012/05/05 08:05:33 mgorny Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/ChangeLog,v 1.26 2013/01/17 21:16:54 billie Exp $
+
+  17 Jan 2013; Daniel Pielmeier <billie@gentoo.org>
+  aqualung-0.9_beta11-r1.ebuild, +aqualung-0.9_beta11-r2.ebuild:
+  Revison bump. Switch to EAPI 5. Reorder deps and configure switches. Other
+  minor changes. Ebuild support for bug #452460. Build with libcdio-paranoia
+  still needs a patch to work.
+
+*aqualung-0.9_beta11-r2 (17 Jan 2013)
+
+  17 Jan 2013; Daniel Pielmeier <billie@gentoo.org>
+  aqualung-0.9_beta11-r1.ebuild, +aqualung-0.9_beta11-r2.ebuild:
+  Revison bump. Switch to EAPI 5. Reorder deps and configure switches. Other
+  minor changes. Ebuild support for bug #452460. Build with libcdio-paranoia
+  still needs a patch to work.
 
   05 May 2012; Michał Górny <mgorny@gentoo.org>
   aqualung-0.9_beta11-r1.ebuild:
diff --git a/media-sound/aqualung/aqualung-0.9_beta11-r1.ebuild b/media-sound/aqualung/aqualung-0.9_beta11-r1.ebuild
index 93436411c3a4..ad991b0012f3 100644
--- a/media-sound/aqualung/aqualung-0.9_beta11-r1.ebuild
+++ b/media-sound/aqualung/aqualung-0.9_beta11-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta11-r1.ebuild,v 1.11 2012/05/05 08:05:33 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta11-r1.ebuild,v 1.12 2013/01/17 21:16:54 billie Exp $
 
 EAPI=4
 
@@ -20,7 +20,7 @@ IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libsamplerate lua
 KEYWORDS="amd64 x86"
 
 RDEPEND="alsa? ( media-libs/alsa-lib )
-	cdda? ( dev-libs/libcdio[-minimal] )
+	cdda? ( || ( dev-libs/libcdio-paranoia <dev-libs/libcdio-0.90[-minimal] ) )
 	cddb? ( media-libs/libcddb )
 	flac? ( media-libs/flac )
 	ffmpeg? ( >=virtual/ffmpeg-0.6.90 )
@@ -57,6 +57,12 @@ src_prepare() {
 		-e '/BUILD_CFLAGS/s:-O2::' \
 		-e '/BUILD_CFLAGS/s: -ggdb -g -O0::' \
 		configure.ac || die
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			-e 's:cdio/paranoia.h:cdio/paranoia/paranoia.h:' \
+			src/*.{c,h} src/decoder/dec_cdda.h || die
+	fi
 	eautoreconf
 }
 
diff --git a/media-sound/aqualung/aqualung-0.9_beta11-r2.ebuild b/media-sound/aqualung/aqualung-0.9_beta11-r2.ebuild
new file mode 100644
index 000000000000..660465914ee0
--- /dev/null
+++ b/media-sound/aqualung/aqualung-0.9_beta11-r2.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta11-r2.ebuild,v 1.1 2013/01/17 21:16:54 billie Exp $
+
+EAPI=5
+
+inherit autotools eutils
+
+MY_PV=${PV/_/}
+
+DESCRIPTION="A music player for a wide range of formats designed for gapless playback"
+HOMEPAGE="http://aqualung.factorial.hu/"
+SRC_URI="mirror://sourceforge/aqualung/${PN}-${MY_PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libsamplerate lua
+	mac modplug mp3 musepack oss podcast pulseaudio sndfile speex systray vorbis wavpack"
+
+RDEPEND="sys-libs/zlib
+	app-arch/bzip2
+	dev-libs/libxml2
+	x11-libs/gtk+:2
+	alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	pulseaudio? ( media-sound/pulseaudio )
+	flac? ( media-libs/flac )
+	lame? ( media-sound/lame )
+	ffmpeg? ( >=virtual/ffmpeg-0.6.90 )
+	mac? ( media-sound/mac )
+	modplug? ( media-libs/libmodplug )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	mp3? ( media-libs/libmad )
+	sndfile? ( media-libs/libsndfile )
+	speex? ( media-libs/speex media-libs/liboggz )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	ladspa? ( media-libs/liblrdf )
+	libsamplerate? ( media-libs/libsamplerate )
+	cdda? ( || ( dev-libs/libcdio-paranoia <dev-libs/libcdio-0.90[-minimal] ) )
+	ifp? ( media-libs/libifp )
+	cddb? ( media-libs/libcddb )
+	lua? ( dev-lang/lua )"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-use_lrdf_cflags.patch \
+		"${FILESDIR}"/${P}-ffmpeg.patch \
+		"${FILESDIR}"/${P}-libavformat54.patch
+	sed -i \
+		-e 's:$(pkgdatadir)/doc:/usr/share/doc/${PF}:' \
+		doc/Makefile.am || die
+	sed -i \
+		-e '/BUILD_CFLAGS/s:-O2::' \
+		-e '/BUILD_CFLAGS/s: -ggdb -g -O0::' \
+		configure.ac || die
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			-e 's:cdio/paranoia.h:cdio/paranoia/paranoia.h:' \
+			src/*.{c,h} src/decoder/dec_cdda.h || die
+	fi
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		$(use_with alsa) \
+		$(use_with jack) \
+		$(use_with oss) \
+		$(use_with pulseaudio pulse) \
+		$(use_with flac) \
+		$(use_with lame) \
+		$(use_with ffmpeg lavc) \
+		$(use_with mac) \
+		$(use_with modplug mod) \
+		$(use_with musepack mpc) \
+		$(use_with podcast) \
+		$(use_with mp3 mpeg) \
+		$(use_with sndfile) \
+		$(use_with speex) \
+		$(use_with systray) \
+		$(use_with vorbis ogg) \
+		$(use_with vorbis vorbisenc) \
+		--with-loop \
+		$(use_with wavpack) \
+		$(use_with ladspa) \
+		$(use_with libsamplerate src) \
+		$(use_with cdda) \
+		$(use_with ifp) \
+		$(use_with cddb) \
+		$(use_with lua) \
+		--docdir=/usr/share/doc/${PF}
+}
+
+src_install() {
+	default
+
+	newicon src/img/icon_64.png aqualung.png
+	make_desktop_entry aqualung Aqualung
+}