Version bump with small fixes for Indic and Hebrew shaping (bug #509456, thanks to DrSlony). And use multilib_native_use_enable for introspection, not _use_with.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

4 files changed, 100 insertions, 6 deletions

diff --git a/media-libs/harfbuzz/ChangeLog b/media-libs/harfbuzz/ChangeLog
index 041a17ff5e1a..7d4bf63bf61c 100644
--- a/media-libs/harfbuzz/ChangeLog
+++ b/media-libs/harfbuzz/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-libs/harfbuzz
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/ChangeLog,v 1.75 2014/04/30 04:53:15 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/ChangeLog,v 1.76 2014/05/04 17:09:27 tetromino Exp $
+
+*harfbuzz-0.9.28 (04 May 2014)
+
+  04 May 2014; Alexandre Rostovtsev <tetromino@gentoo.org>
+  harfbuzz-0.9.26-r1.ebuild, +harfbuzz-0.9.28.ebuild, harfbuzz-9999.ebuild:
+  Version bump with small fixes for Indic and Hebrew shaping (bug #509456,
+  thanks to DrSlony). And use multilib_native_use_enable for introspection, not
+  _use_with.
 
   30 Apr 2014; Tim Harder <radhermit@gentoo.org> harfbuzz-0.9.26-r1.ebuild:
   Sync mips keywords.
diff --git a/media-libs/harfbuzz/harfbuzz-0.9.26-r1.ebuild b/media-libs/harfbuzz/harfbuzz-0.9.26-r1.ebuild
index 7bc8cde2e589..24ccd0f4341e 100644
--- a/media-libs/harfbuzz/harfbuzz-0.9.26-r1.ebuild
+++ b/media-libs/harfbuzz/harfbuzz-0.9.26-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/harfbuzz-0.9.26-r1.ebuild,v 1.4 2014/04/30 04:53:15 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/harfbuzz-0.9.26-r1.ebuild,v 1.5 2014/05/04 17:09:27 tetromino Exp $
 
 EAPI=5
 
@@ -77,7 +77,7 @@ multilib_src_configure() {
 		$(use_with glib gobject) \
 		$(use_with graphite graphite2) \
 		$(use_with icu) \
-		$(multilib_native_use_with introspection) \
+		$(multilib_native_use_enable introspection) \
 		$(use_with truetype freetype)
 }
 
diff --git a/media-libs/harfbuzz/harfbuzz-0.9.28.ebuild b/media-libs/harfbuzz/harfbuzz-0.9.28.ebuild
new file mode 100644
index 000000000000..e83e78192a70
--- /dev/null
+++ b/media-libs/harfbuzz/harfbuzz-0.9.28.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/harfbuzz-0.9.28.ebuild,v 1.1 2014/05/04 17:09:27 tetromino Exp $
+
+EAPI=5
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/harfbuzz"
+[[ ${PV} == 9999 ]] && inherit git-2 autotools
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit eutils libtool multilib-minimal python-any-r1
+
+DESCRIPTION="An OpenType text shaping engine"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/HarfBuzz"
+[[ ${PV} == 9999 ]] || SRC_URI="http://www.freedesktop.org/software/${PN}/release/${P}.tar.bz2"
+
+LICENSE="Old-MIT ISC icu"
+SLOT="0/0.9.18" # 0.9.18 introduced the harfbuzz-icu split; bug #472416
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris"
+IUSE="+cairo +glib +graphite icu +introspection static-libs test +truetype"
+REQUIRED_USE="introspection? ( glib )"
+
+RDEPEND="
+	cairo? ( x11-libs/cairo:= )
+	glib? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
+	graphite? ( media-gfx/graphite2:=[${MULTILIB_USEDEP}] )
+	icu? ( dev-libs/icu:=[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34 )
+	truetype? ( media-libs/freetype:2=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )
+"
+# eautoreconf requires gobject-introspection-common
+# ragel needed if regenerating *.hh files from *.rl
+[[ ${PV} = 9999 ]] && DEPEND="${DEPEND}
+	>=dev-libs/gobject-introspection-common-1.34
+	dev-util/ragel
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	if [[ ${CHOST} == *-darwin* || ${CHOST} == *-solaris* ]] ; then
+		# on Darwin/Solaris we need to link with g++, like automake defaults
+		# to, but overridden by upstream because on Linux this is not
+		# necessary, bug #449126
+		sed -i \
+			-e 's/\<LINK\>/CXXLINK/' \
+			src/Makefile.am || die
+		sed -i \
+			-e '/libharfbuzz_la_LINK = /s/\<LINK\>/CXXLINK/' \
+			src/Makefile.in || die
+		sed -i \
+			-e '/AM_V_CCLD/s/\<LINK\>/CXXLINK/' \
+			test/api/Makefile.in || die
+	fi
+
+	[[ ${PV} == 9999 ]] && eautoreconf
+	elibtoolize # for Solaris
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	econf \
+		--without-coretext \
+		--without-uniscribe \
+		$(use_enable static-libs static) \
+		$(multilib_native_use_with cairo) \
+		$(use_with glib) \
+		$(use_with glib gobject) \
+		$(use_with graphite graphite2) \
+		$(use_with icu) \
+		$(multilib_native_use_enable introspection) \
+		$(use_with truetype freetype)
+}
+
+multilib_src_install_all() {
+	prune_libtool_files --modules
+}
diff --git a/media-libs/harfbuzz/harfbuzz-9999.ebuild b/media-libs/harfbuzz/harfbuzz-9999.ebuild
index 88390b1319c6..cd4a3f609df9 100644
--- a/media-libs/harfbuzz/harfbuzz-9999.ebuild
+++ b/media-libs/harfbuzz/harfbuzz-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/harfbuzz-9999.ebuild,v 1.25 2014/04/28 18:10:00 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/harfbuzz/harfbuzz-9999.ebuild,v 1.26 2014/05/04 17:09:27 tetromino Exp $
 
 EAPI=5
 
@@ -18,7 +18,7 @@ HOMEPAGE="http://www.freedesktop.org/wiki/Software/HarfBuzz"
 LICENSE="Old-MIT ISC icu"
 SLOT="0/0.9.18" # 0.9.18 introduced the harfbuzz-icu split; bug #472416
 [[ ${PV} == 9999 ]] || \
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris"
 IUSE="+cairo +glib +graphite icu +introspection static-libs test +truetype"
 REQUIRED_USE="introspection? ( glib )"
 
@@ -77,7 +77,7 @@ multilib_src_configure() {
 		$(use_with glib gobject) \
 		$(use_with graphite graphite2) \
 		$(use_with icu) \
-		$(multilib_native_use_with introspection) \
+		$(multilib_native_use_enable introspection) \
 		$(use_with truetype freetype)
 }