Convert to multilib and stack it for baselib r11

(Portage version: 2.2.0_alpha196/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 73 insertions, 1 deletions

diff --git a/media-libs/tiff/ChangeLog b/media-libs/tiff/ChangeLog
index 0862408dcd4a..669ed729755b 100644
--- a/media-libs/tiff/ChangeLog
+++ b/media-libs/tiff/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/tiff
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/tiff/ChangeLog,v 1.237 2013/08/10 17:15:29 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/tiff/ChangeLog,v 1.238 2013/08/10 23:13:32 aballier Exp $
+
+*tiff-3.9.7-r1 (10 Aug 2013)
+
+  10 Aug 2013; Alexis Ballier <aballier@gentoo.org> +tiff-3.9.7-r1.ebuild:
+  Convert to multilib and stack it for baselib r11
 
   10 Aug 2013; Alexis Ballier <aballier@gentoo.org> tiff-4.0.3-r3.ebuild:
   Add blockers on emul-libs so that it is stacked for baselibs r10
diff --git a/media-libs/tiff/tiff-3.9.7-r1.ebuild b/media-libs/tiff/tiff-3.9.7-r1.ebuild
new file mode 100644
index 000000000000..31e1b03ac1e6
--- /dev/null
+++ b/media-libs/tiff/tiff-3.9.7-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/tiff/tiff-3.9.7-r1.ebuild,v 1.1 2013/08/10 23:13:32 aballier Exp $
+
+EAPI=5
+
+# this ebuild is only for the libtiff.so.3 (+ 4) and libtiffxx.so.3 (+ 4) SONAME for ABI compat
+
+inherit eutils libtool multilib multilib-minimal
+
+DESCRIPTION="Library for manipulation of TIFF (Tag Image File Format) images"
+HOMEPAGE="http://www.remotesensing.org/libtiff/"
+SRC_URI="ftp://ftp.remotesensing.org/pub/libtiff/${P}.tar.gz"
+
+LICENSE="libtiff"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="+cxx jbig jpeg zlib"
+
+RDEPEND="jpeg? ( virtual/jpeg[${MULTILIB_USEDEP}] )
+	jbig? ( media-libs/jbigkit[${MULTILIB_USEDEP}] )
+	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
+	!media-libs/tiff-compat
+	!=media-libs/tiff-3*:0
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20130224-r10
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-CVE-2012-{4447,4564,5581}.patch \
+		"${FILESDIR}"/${P}-tiffinfo-exif.patch \
+		"${FILESDIR}"/${P}-printdir-width.patch
+
+	elibtoolize
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		--libdir=/libdir \
+		--disable-static \
+		$(use_enable cxx) \
+		$(use_enable zlib) \
+		$(use_enable jpeg) \
+		$(use_enable jbig) \
+		--without-x
+}
+
+multilib_src_install() {
+	# Let `make install` and libtool handle insecure runpath(s)
+	dodir tmp
+	emake DESTDIR="${ED}/tmp" install
+
+	# .so.3 (upstream) is used by sci-chemistry/icm
+	# .so.4 (Debian) is used by net-im/skype
+	exeinto /usr/$(get_libdir)
+	doexe "${ED}"/tmp/libdir/libtiff$(get_libname 3)
+	dosym libtiff$(get_libname 3) /usr/$(get_libdir)/libtiff$(get_libname 4)
+	if use cxx; then
+		doexe "${ED}"/tmp/libdir/libtiffxx$(get_libname 3)
+		dosym libtiffxx$(get_libname 3) /usr/$(get_libdir)/libtiffxx$(get_libname 4)
+	fi
+
+	rm -rf "${ED}"/tmp
+}