Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

3 files changed, 115 insertions, 4 deletions

diff --git a/media-libs/phonon/ChangeLog b/media-libs/phonon/ChangeLog
index 2587bdf3da68..44395dce7d3f 100644
--- a/media-libs/phonon/ChangeLog
+++ b/media-libs/phonon/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/phonon
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon/ChangeLog,v 1.59 2014/08/17 13:02:06 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon/ChangeLog,v 1.60 2014/09/09 17:17:26 kensington Exp $
+
+*phonon-4.8.0 (09 Sep 2014)
+
+  09 Sep 2014; Michael Palimaka <kensington@gentoo.org> +phonon-4.8.0.ebuild,
+  phonon-9999.ebuild:
+  Version bump.
 
   17 Aug 2014; Jeroen Roovers <jer@gentoo.org> phonon-4.7.2.ebuild:
   Stable for HPPA (bug #519592).
diff --git a/media-libs/phonon/phonon-4.8.0.ebuild b/media-libs/phonon/phonon-4.8.0.ebuild
new file mode 100644
index 000000000000..39801cc7d67d
--- /dev/null
+++ b/media-libs/phonon/phonon-4.8.0.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon/phonon-4.8.0.ebuild,v 1.1 2014/09/09 17:17:26 kensington Exp $
+
+EAPI=5
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="mirror://kde/stable/phonon/${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+else
+	SCM_ECLASS="git-r3"
+	EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
+	KEYWORDS=""
+fi
+
+inherit cmake-utils multibuild ${SCM_ECLASS}
+
+DESCRIPTION="KDE multimedia API"
+HOMEPAGE="https://projects.kde.org/projects/kdesupport/phonon"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="aqua debug designer gstreamer pulseaudio +qt4 qt5 +vlc zeitgeist"
+
+REQUIRED_USE="
+	|| ( aqua gstreamer vlc )
+	|| ( qt4 qt5 )
+	zeitgeist? ( qt4 )
+"
+
+RDEPEND="
+	!!dev-qt/qtphonon:4
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+		designer? ( dev-qt/designer:4 )
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		designer? ( dev-qt/designer:5 )
+	)
+	pulseaudio? (
+		dev-libs/glib:2
+		>=media-sound/pulseaudio-0.9.21[glib]
+	)
+	zeitgeist? ( dev-libs/libqzeitgeist )
+"
+DEPEND="${RDEPEND}
+	qt4? ( >=dev-util/automoc-0.9.87 )
+	virtual/pkgconfig
+"
+PDEPEND="
+	aqua? ( media-libs/phonon-qt7 )
+	gstreamer? ( >=media-libs/phonon-gstreamer-4.8.0[qt4?,qt5?] )
+	vlc? ( >=media-libs/phonon-vlc-0.8.0[qt4?,qt5?] )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-4.7.0-plugin-install.patch" )
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=()
+	if use qt4; then
+		MULTIBUILD_VARIANTS+=(qt4)
+	fi
+	if use qt5; then
+		MULTIBUILD_VARIANTS+=(qt5)
+	fi
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DPHONON_INSTALL_QT_EXTENSIONS_INTO_SYSTEM_QT=TRUE
+			$(cmake-utils_use designer PHONON_BUILD_DESIGNER_PLUGIN)
+			$(cmake-utils_use_with pulseaudio GLIB2)
+			$(cmake-utils_use_with pulseaudio PulseAudio)
+			$(cmake-utils_use_with zeitgeist QZeitgeist)
+		)
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=OFF)
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=ON)
+		fi
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}
diff --git a/media-libs/phonon/phonon-9999.ebuild b/media-libs/phonon/phonon-9999.ebuild
index d6bc009e1314..c07fbb38494d 100644
--- a/media-libs/phonon/phonon-9999.ebuild
+++ b/media-libs/phonon/phonon-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon/phonon-9999.ebuild,v 1.24 2014/08/10 21:42:11 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon/phonon-9999.ebuild,v 1.25 2014/09/09 17:17:26 kensington Exp $
 
 EAPI=5
 
@@ -55,8 +55,8 @@ DEPEND="${RDEPEND}
 "
 PDEPEND="
 	aqua? ( media-libs/phonon-qt7 )
-	gstreamer? ( >=media-libs/phonon-gstreamer-4.7.0[qt4?,qt5?] )
-	vlc? ( >=media-libs/phonon-vlc-0.7.0[qt4?,qt5?] )
+	gstreamer? ( >=media-libs/phonon-gstreamer-4.8.0[qt4?,qt5?] )
+	vlc? ( >=media-libs/phonon-vlc-0.8.0[qt4?,qt5?] )
 "
 
 PATCHES=( "${FILESDIR}/${PN}-4.7.0-plugin-install.patch" )