Version bump

(Portage version: 2.1.11.50/cvs/Linux x86_64, signed Manifest commit with key B4AFF2C2)

2 files changed, 70 insertions, 2 deletions

diff --git a/lxde-base/lxpanel/ChangeLog b/lxde-base/lxpanel/ChangeLog
index 9d07570a4b35..b39d3318c7f4 100644
--- a/lxde-base/lxpanel/ChangeLog
+++ b/lxde-base/lxpanel/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for lxde-base/lxpanel
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v 1.51 2012/08/25 00:03:51 hwoarang Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v 1.52 2013/01/26 17:46:58 hwoarang Exp $
+
+*lxpanel-0.5.12 (26 Jan 2013)
+
+  26 Jan 2013; Markos Chandras <hwoarang@gentoo.org> +lxpanel-0.5.12.ebuild:
+  Version bump
 
   25 Aug 2012; Markos Chandras <hwoarang@gentoo.org>
   -files/lxpanel-0.5.1-sandbox.patch, -files/lxpanel-0.5.6-broken-apps.patch,
diff --git a/lxde-base/lxpanel/lxpanel-0.5.12.ebuild b/lxde-base/lxpanel/lxpanel-0.5.12.ebuild
new file mode 100644
index 000000000000..07b572e7669e
--- /dev/null
+++ b/lxde-base/lxpanel/lxpanel-0.5.12.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/lxpanel-0.5.12.ebuild,v 1.1 2013/01/26 17:46:58 hwoarang Exp $
+
+EAPI="4"
+
+inherit autotools eutils
+
+DESCRIPTION="Lightweight X11 desktop panel for LXDE"
+HOMEPAGE="http://lxde.org/"
+SRC_URI="mirror://sourceforge/lxde/LXPanel%20%28desktop%20panel%29/LXPanel%20${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~x86 ~x86-interix ~amd64-linux ~x86-linux"
+SLOT="0"
+IUSE="+alsa wifi"
+RESTRICT="test"  # bug 249598
+
+RDEPEND="x11-libs/gtk+:2
+	x11-libs/libXmu
+	x11-libs/libXpm
+	lxde-base/lxmenu-data
+	lxde-base/menu-cache
+	alsa? ( media-libs/alsa-lib )
+	wifi? ( net-wireless/wireless-tools )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.5.9-sandbox.patch
+	#bug #415595
+	epatch "${FILESDIR}"/${PN}-0.5.9-libwnck-check.patch
+	#bug #420583
+	sed -i "s:-Werror::" configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local plugins="netstatus,volume,cpu deskno,batt, \
+		kbled,xkb,thermal,cpufreq,monitors"
+	# wnckpager disabled per bug #415519
+	use wifi && plugins+=",netstat"
+	use alsa && plugins+=",volumealsa"
+	[[ ${CHOST} == *-interix* ]] && plugins=deskno,kbled,xkb
+
+	econf $(use_enable alsa) --with-x --with-plugins="${plugins}"
+	# the gtk+ dep already pulls in libX11, so we might as well hardcode with-x
+}
+
+src_install () {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README
+
+	# Get rid of the .la files.
+	find "${D}" -name '*.la' -delete
+}
+
+pkg_postinst() {
+	elog "If you have problems with broken icons shown in the main panel,"
+	elog "you will have to configure panel settings via its menu."
+	elog "This will not be an issue with first time installations."
+}