Version bump thanks to jospezial. Bug #524654

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)

2 files changed, 78 insertions, 1 deletions

diff --git a/lxde-base/lxpanel/ChangeLog b/lxde-base/lxpanel/ChangeLog
index 2e44dd9d0e54..033a8d6f509f 100644
--- a/lxde-base/lxpanel/ChangeLog
+++ b/lxde-base/lxpanel/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for lxde-base/lxpanel
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v 1.64 2015/03/03 08:06:53 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/ChangeLog,v 1.65 2015/05/17 16:25:46 hwoarang Exp $
+
+*lxpanel-0.8.1 (17 May 2015)
+
+  17 May 2015; Markos Chandras <hwoarang@gentoo.org> +lxpanel-0.8.1.ebuild:
+  Version bump thanks to jospezial. Bug #524654
 
   03 Mar 2015; Yixun Lan <dlan@gentoo.org> lxpanel-0.7.0-r1.ebuild:
   add arm64 support, tested on A53 board
diff --git a/lxde-base/lxpanel/lxpanel-0.8.1.ebuild b/lxde-base/lxpanel/lxpanel-0.8.1.ebuild
new file mode 100644
index 000000000000..e8c3e2a96d9c
--- /dev/null
+++ b/lxde-base/lxpanel/lxpanel-0.8.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/lxpanel-0.8.1.ebuild,v 1.1 2015/05/17 16:25:46 hwoarang Exp $
+
+EAPI="5"
+
+inherit autotools eutils readme.gentoo versionator
+
+MAJOR_VER="$(get_version_component_range 1-2)"
+
+DESCRIPTION="Lightweight X11 desktop panel for LXDE"
+HOMEPAGE="http://lxde.org/"
+SRC_URI="mirror://sourceforge/lxde/LXPanel%20%28desktop%20panel%29/LXPanel%20${MAJOR_VER}.x/${P}.tar.xz"
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86 ~x86-interix ~amd64-linux ~arm-linux ~x86-linux"
+SLOT="0"
+IUSE="+alsa wifi"
+RESTRICT="test"  # bug 249598
+
+RDEPEND="dev-libs/keybinder:0=
+	x11-libs/gtk+:2
+	>=x11-libs/libfm-1.2.0[gtk]
+	x11-libs/libwnck:1
+	x11-libs/libXmu
+	x11-libs/libXpm
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/libX11
+	lxde-base/lxmenu-data
+	lxde-base/menu-cache
+	alsa? ( media-libs/alsa-lib )
+	wifi? ( net-wireless/wireless-tools )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+DOC_CONTENTS="If you have problems with broken icons shown in the main panel,
+you will have to configure panel settings via its menu.
+This will not be an issue with first time installations."
+
+src_prepare() {
+	#bug #415595
+	sed -i "s:-Werror::" configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local plugins="netstatus,volume,cpu,deskno,batt, \
+		kbled,xkb,thermal,cpufreq,monitors"
+
+	use wifi && plugins+=",netstat"
+	use alsa && plugins+=",volumealsa"
+	[[ ${CHOST} == *-interix* ]] && plugins=deskno,kbled,xkb
+
+	econf $(use_enable alsa) --with-x --with-plugins="${plugins}"
+	# the gtk+ dep already pulls in libX11, so we might as well hardcode with-x
+}
+
+src_install () {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README
+
+	# Get rid of the .la files.
+	find "${D}" -name '*.la' -delete
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}