Fixes battery metter always showing 100 percent charge, patch thanks to Robert Meyer <r.meyer@net-wizard.org> bug #389581

(Portage version: 2.1.10.11/cvs/Linux x86_64)

1 files changed, 56 insertions, 0 deletions

diff --git a/lxde-base/lxpanel/lxpanel-0.5.8-r1.ebuild b/lxde-base/lxpanel/lxpanel-0.5.8-r1.ebuild
new file mode 100644
index 000000000000..6bd20e35d832
--- /dev/null
+++ b/lxde-base/lxpanel/lxpanel-0.5.8-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxpanel/lxpanel-0.5.8-r1.ebuild,v 1.1 2012/01/01 13:39:25 vostorga Exp $
+
+EAPI="4"
+
+inherit autotools eutils
+
+DESCRIPTION="Lightweight X11 desktop panel for LXDE"
+HOMEPAGE="http://lxde.org/"
+SRC_URI="mirror://sourceforge/lxde/${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~x86 ~x86-interix ~amd64-linux ~x86-linux"
+SLOT="0"
+IUSE="+alsa"
+RESTRICT="test"  # bug 249598
+
+RDEPEND="x11-libs/gtk+:2
+	x11-libs/libXmu
+	x11-libs/libXpm
+	lxde-base/lxmenu-data
+	lxde-base/menu-cache
+	alsa? ( media-libs/alsa-lib )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.5.1-sandbox.patch
+	epatch "${FILESDIR}"/${PN}-0.5.6-broken-apps.patch
+	epatch "${FILESDIR}"/${P}-battery-meter.patch
+	eautoreconf
+}
+
+src_configure() {
+	local plugins=all
+	[[ ${CHOST} == *-interix* ]] && plugins=deskno,kbled,xkb
+
+	econf $(use_enable alsa) --with-x --with-plugins=${plugins}
+	# the gtk+ dep already pulls in libX11, so we might as well hardcode with-x
+}
+
+src_install () {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README
+
+	# Get rid of the .la files.
+	find "${D}" -name '*.la' -delete
+}
+
+pkg_postinst() {
+	elog "If you have problems with broken icons shown in the main panel,"
+	elog "you will have to configure panel settings via its menu."
+	elog "This will not be an issue with first time installations."
+}