Version bump KDE 4.3.4

(Portage version: 2.2_rc54/cvs/Linux x86_64, RepoMan options: --force)

2 files changed, 78 insertions, 1 deletions

diff --git a/kde-base/kde-l10n/ChangeLog b/kde-base/kde-l10n/ChangeLog
index 3ed6db4e3dea..bc97d1178755 100644
--- a/kde-base/kde-l10n/ChangeLog
+++ b/kde-base/kde-l10n/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kde-l10n
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.47 2009/11/30 06:53:42 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.48 2009/12/01 10:22:17 wired Exp $
+
+*kde-l10n-4.3.4 (01 Dec 2009)
+
+  01 Dec 2009; Alex Alexander <wired@gentoo.org> +kde-l10n-4.3.4.ebuild:
+  Version bump
 
   30 Nov 2009; Joseph Jezak <josejx@gentoo.org> kde-l10n-4.3.3.ebuild:
   Marked ppc/ppc64 stable for bug #292455.
diff --git a/kde-base/kde-l10n/kde-l10n-4.3.4.ebuild b/kde-base/kde-l10n/kde-l10n-4.3.4.ebuild
new file mode 100644
index 000000000000..6dfefcb6e811
--- /dev/null
+++ b/kde-base/kde-l10n/kde-l10n-4.3.4.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.3.4.ebuild,v 1.1 2009/12/01 10:22:17 wired Exp $
+
+EAPI="2"
+
+inherit kde4-base
+
+DESCRIPTION="KDE internationalization package"
+HOMEPAGE="http://www.kde.org/"
+LICENSE="GPL-2"
+
+DEPEND="sys-devel/gettext"
+RDEPEND=""
+
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="+handbook"
+
+MY_LANGS="ar bg bn_IN ca cs csb da de el en_GB es et eu fi fr ga gl gu he hi
+	hne hr hu is it ja kk km kn ko ku lt lv mai mk ml mr nb nds nl nn pa pl pt
+	pt_BR ro ru sk sl sr sv tg th tr uk wa zh_CN zh_TW"
+
+URI_BASE="${SRC_URI/-${PV}.tar.bz2/}"
+SRC_URI=""
+
+for MY_LANG in ${MY_LANGS} ; do
+	IUSE="${IUSE} linguas_${MY_LANG}"
+	SRC_URI="${SRC_URI} linguas_${MY_LANG}? ( ${URI_BASE}/${PN}-${MY_LANG}-${PV}.tar.bz2 )"
+done
+
+S="${WORKDIR}"
+
+src_unpack() {
+	local LNG DIR
+	if [[ -z ${A} ]]; then
+		elog
+		elog "You either have the LINGUAS variable unset, or it only"
+		elog "contains languages not supported by ${P}."
+		elog "You won't have any additional language support."
+		elog
+		elog "${P} supports these language codes:"
+		elog "${MY_LANGS}"
+		elog
+	fi
+
+	[[ -n ${A} ]] && unpack ${A}
+	cd "${S}"
+
+	# add all linguas to cmake
+	if [[ -n ${A} ]]; then
+		for LNG in ${LINGUAS}; do
+			DIR="${PN}-${LNG}-${PV}"
+			if [[ -d "${DIR}" ]] ; then
+				echo "add_subdirectory( ${DIR} )" >> "${S}"/CMakeLists.txt
+			fi
+		done
+	fi
+}
+
+src_configure() {
+	mycmakeargs="${mycmakeargs}
+		$(cmake-utils_use_build handbook docs)"
+	[[ -n ${A} ]] && kde4-base_src_configure
+}
+
+src_compile() {
+	[[ -n ${A} ]] && kde4-base_src_compile
+}
+
+src_install() {
+	[[ -n ${A} ]] && kde4-base_src_install
+}