version bump (bug #535818)

(Portage version: 2.2.14/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 107 insertions, 2 deletions

diff --git a/games-strategy/lgeneral/ChangeLog b/games-strategy/lgeneral/ChangeLog
index ac0fdbc58bc5..a7b7998b4b76 100644
--- a/games-strategy/lgeneral/ChangeLog
+++ b/games-strategy/lgeneral/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-strategy/lgeneral
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/lgeneral/ChangeLog,v 1.45 2014/10/20 07:00:23 tupone Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/lgeneral/ChangeLog,v 1.46 2015/01/07 09:50:47 mr_bones_ Exp $
+
+*lgeneral-1.2.4 (07 Jan 2015)
+
+  07 Jan 2015; Michael Sterrett <mr_bones_@gentoo.org> +lgeneral-1.2.4.ebuild:
+  version bump (bug #535818)
 
   20 Oct 2014; Alfredo Tupone <tupone@gentoo.org> lgeneral-1.2.3.ebuild,
   +files/lgeneral-1.2.3-format.patch:
diff --git a/games-strategy/lgeneral/lgeneral-1.2.4.ebuild b/games-strategy/lgeneral/lgeneral-1.2.4.ebuild
new file mode 100644
index 000000000000..6044e8bc930c
--- /dev/null
+++ b/games-strategy/lgeneral/lgeneral-1.2.4.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/lgeneral/lgeneral-1.2.4.ebuild,v 1.1 2015/01/07 09:50:47 mr_bones_ Exp $
+
+EAPI=5
+inherit eutils autotools gnome2-utils games
+
+MY_P="${P/_/}"
+MY_P="${MY_P/beta/beta-}"
+DESCRIPTION="A Panzer General clone written in SDL"
+HOMEPAGE="http://lgames.sourceforge.net/index.php?project=LGeneral"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz
+	mirror://sourceforge/${PN}/pg-data.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND="media-libs/libsdl[sound,video]
+	media-libs/sdl-mixer
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	sed -i \
+		-e '/desktop_DATA/d' \
+		-e '/icon_DATA/d' \
+		Makefile.am || die
+
+	cp /usr/share/gettext/config.rpath .
+	rm -f missing
+	mv configure.in configure.ac
+	eautoreconf
+
+	# Build a temporary lgc-pg that knows about ${WORKDIR}:
+	cp -pPR "${S}" "${WORKDIR}"/tmp-build || die
+	sed -i \
+		-e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}:" \
+		-e "s:@D@::" \
+		{lgc-pg,src}/misc.c || die
+
+	cd "${WORKDIR}"/tmp-build || die
+	sed -i \
+		-e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}:" \
+		-e "s:@D@:${D}:" \
+		{lgc-pg,src}/misc.c || die
+}
+
+src_configure() {
+	egamesconf \
+		$(use_enable nls)
+
+	# Build the temporary lgc-pg:
+	cd "${WORKDIR}"/tmp-build || die
+	egamesconf \
+		--disable-nls \
+		--datadir="${D}/${GAMES_DATADIR}"
+}
+
+src_compile() {
+	emake
+
+	# Build the temporary lgc-pg:
+	cd "${WORKDIR}"/tmp-build || die
+	emake
+}
+
+src_install() {
+	default
+	keepdir "${GAMES_DATADIR}"/${PN}/{ai_modules,music,terrain}
+
+	# Generate scenario data:
+	dodir "${GAMES_DATADIR}"/${PN}/gfx/{flags,units,terrain} #413901
+	SDL_VIDEODRIVER=dummy "${WORKDIR}"/tmp-build/lgc-pg/lgc-pg \
+		-s "${WORKDIR}"/pg-data \
+		-d "${D}/${GAMES_DATADIR}"/${PN} \
+		|| die
+
+	newicon -s 48 lgeneral48.png ${PN}.png
+	make_desktop_entry ${PN} LGeneral
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}