version bump (bug #390065)

(Portage version: 2.1.10.41/cvs/Linux i686)

2 files changed, 106 insertions, 1 deletions

diff --git a/games-roguelike/angband/ChangeLog b/games-roguelike/angband/ChangeLog
index 3d13c39ace6f..9f429edc4f78 100644
--- a/games-roguelike/angband/ChangeLog
+++ b/games-roguelike/angband/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-roguelike/angband
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/ChangeLog,v 1.39 2011/03/11 07:44:03 tomka Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/ChangeLog,v 1.40 2011/12/20 00:19:32 mr_bones_ Exp $
+
+*angband-3.3.2 (20 Dec 2011)
+
+  20 Dec 2011; Michael Sterrett <mr_bones_@gentoo.org> +angband-3.3.2.ebuild:
+  version bump (bug #390065)
 
   11 Mar 2011; Thomas Kahle <tomka@gentoo.org> angband-3.2.0.ebuild:
   x86 stable per bug 355107
diff --git a/games-roguelike/angband/angband-3.3.2.ebuild b/games-roguelike/angband/angband-3.3.2.ebuild
new file mode 100644
index 000000000000..04a428d90edb
--- /dev/null
+++ b/games-roguelike/angband/angband-3.3.2.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/angband-3.3.2.ebuild,v 1.1 2011/12/20 00:19:32 mr_bones_ Exp $
+
+EAPI=2
+inherit autotools eutils versionator games
+
+MAJOR_PV=$(get_version_component_range 1-2)
+MY_P=${PN}-v${PV}
+
+DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
+HOMEPAGE="http://rephial.org/"
+SRC_URI="http://rephial.org/downloads/${MAJOR_PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="gtk ncurses sdl +sound X"
+
+RDEPEND="gtk? ( gnome-base/libglade
+	   x11-libs/pango
+	   x11-libs/gtk+:2
+	   dev-libs/glib:2 )
+	X? ( x11-libs/libSM
+		 x11-libs/libX11 )
+	!ncurses? ( !X? ( !sdl? ( !gtk? ( sys-libs/ncurses ) ) ) )
+	sdl? ( media-libs/libsdl[video,X]
+		media-libs/sdl-ttf
+		media-libs/sdl-image
+		sound? ( media-libs/sdl-mixer
+			media-libs/libsdl[audio] ) )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	local myconf
+
+	if use sdl; then
+		myconf="$(use_enable sound sdl-mixer)"
+	else
+		myconf="--disable-sdl-mixer"
+	fi
+
+	egamesconf \
+		--bindir="${GAMES_BINDIR}" \
+		--with-configpath="${GAMES_SYSCONFDIR}/${PN}" \
+		--with-libpath="${GAMES_DATADIR}/${PN}" \
+		--with-varpath="${GAMES_STATEDIR}/${PN}" \
+		--with-private-dirs \
+		$(use_enable X x11) \
+		$(use_enable gtk) \
+		$(use_enable sdl) \
+		$(use_enable ncurses curses) \
+		$( use !gtk && use !sdl && use !ncurses && use !X && \
+			echo --enable-curses) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	# Edit files are now system config files in Angband, but
+	# users will be hidden from applying updates by default
+	echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/edit/\"" \
+		> "${T}"/99${PN}
+	doenvd "${T}"/99${PN} || die
+
+	dodoc changes.txt faq.txt readme.txt thanks.txt || die
+
+	# Create desktop entries if required.
+	ICON_LOC="${GAMES_DATADIR}/${PN}/xtra/icon/att-32.png"
+	if use X; then
+		make_desktop_entry "angband -mx11" "Angband (X11)" "${ICON_LOC}" || die
+	fi
+
+	if use sdl; then
+		make_desktop_entry "angband -msdl" "Angband (SDL)" "${ICON_LOC}" || die
+	fi
+
+	if use gtk; then
+		make_desktop_entry "angband -mgtk" "Angband (GTK)" "${ICON_LOC}" || die
+	fi
+
+	use ncurses || rm -rf "${D}${GAMES_DATADIR}/${PN}/xtra/graf"
+	use sound || rm -rf "${D}${GAMES_DATADIR}/${PN}/xtra/sound"
+
+	prepgamesdirs
+}
+
+pkg_postinst() {
+	echo
+	elog "Angband now uses private savefiles instead of system-wide ones"
+	elog "This version of Angband is not compatible with the save files"
+	elog "of previous versions"
+	echo
+
+	games_pkg_postinst
+}