Version Bump, Reordering the ebuild layout

(Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

5 files changed, 133 insertions, 18 deletions

diff --git a/dev-vcs/cola/ChangeLog b/dev-vcs/cola/ChangeLog
index 1daecb6adb9e..04a9a4a55010 100644
--- a/dev-vcs/cola/ChangeLog
+++ b/dev-vcs/cola/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-vcs/cola
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/cola/ChangeLog,v 1.9 2011/04/16 10:08:24 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/cola/ChangeLog,v 1.10 2011/04/23 07:05:25 jlec Exp $
+
+*cola-1.4.3.3 (23 Apr 2011)
+
+  23 Apr 2011; Justin Lecher <jlec@gentoo.org> cola-1.4.3.1.ebuild,
+  cola-1.4.3.2.ebuild, cola-1.4.3.2-r1.ebuild, +cola-1.4.3.3.ebuild:
+  Version Bump, Reordering the ebuild layout
 
 *cola-1.4.3.2-r1 (16 Apr 2011)
 
diff --git a/dev-vcs/cola/cola-1.4.3.1.ebuild b/dev-vcs/cola/cola-1.4.3.1.ebuild
index 84af4a12be26..681dc2179de2 100644
--- a/dev-vcs/cola/cola-1.4.3.1.ebuild
+++ b/dev-vcs/cola/cola-1.4.3.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/cola/cola-1.4.3.1.ebuild,v 1.1 2011/03/30 08:55:29 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/cola/cola-1.4.3.1.ebuild,v 1.2 2011/04/23 07:05:25 jlec Exp $
 
 EAPI="3"
 
@@ -17,12 +17,14 @@ SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="doc test"
 
-RDEPEND="dev-python/PyQt4
-	>=dev-python/pyinotify-0.7.1
+RDEPEND="
 	dev-python/jsonpickle
-	>=dev-vcs/git-1.6.3"
+	dev-python/pyinotify
+	dev-python/PyQt4
+	dev-vcs/git"
 DEPEND="${RDEPEND}
-	doc? ( app-text/asciidoc
+	doc? (
+		app-text/asciidoc
 		dev-python/sphinx
 		app-text/xmlto )
 	sys-devel/gettext
@@ -49,7 +51,7 @@ src_prepare() {
 	# don't prefix install path with homedir
 	rm setup.cfg
 
-	epatch "${FILESDIR}/1.3.8-disable-tests.patch"
+	epatch "${FILESDIR}"/1.3.8-disable-tests.patch
 
 	python_convert_shebangs 2 bin/git-cola share/git-cola/bin/ssh-askpass
 }
diff --git a/dev-vcs/cola/cola-1.4.3.2-r1.ebuild b/dev-vcs/cola/cola-1.4.3.2-r1.ebuild
index 8ed7bd1a4293..9e4a885997d0 100644
--- a/dev-vcs/cola/cola-1.4.3.2-r1.ebuild
+++ b/dev-vcs/cola/cola-1.4.3.2-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/cola/cola-1.4.3.2-r1.ebuild,v 1.1 2011/04/16 10:08:24 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/cola/cola-1.4.3.2-r1.ebuild,v 1.2 2011/04/23 07:05:25 jlec Exp $
 
 EAPI="3"
 
@@ -17,12 +17,14 @@ SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="doc test"
 
-RDEPEND="dev-python/PyQt4
-	>=dev-python/pyinotify-0.7.1
+RDEPEND="
 	dev-python/jsonpickle
-	>=dev-vcs/git-1.6.3"
+	dev-python/pyinotify
+	dev-python/PyQt4
+	dev-vcs/git"
 DEPEND="${RDEPEND}
-	doc? ( app-text/asciidoc
+	doc? (
+		app-text/asciidoc
 		dev-python/sphinx
 		app-text/xmlto )
 	sys-devel/gettext
diff --git a/dev-vcs/cola/cola-1.4.3.2.ebuild b/dev-vcs/cola/cola-1.4.3.2.ebuild
index 259ec365c16b..523e8ed7b586 100644
--- a/dev-vcs/cola/cola-1.4.3.2.ebuild
+++ b/dev-vcs/cola/cola-1.4.3.2.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/cola/cola-1.4.3.2.ebuild,v 1.1 2011/04/13 19:00:02 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/cola/cola-1.4.3.2.ebuild,v 1.2 2011/04/23 07:05:25 jlec Exp $
 
 EAPI="3"
 
@@ -17,12 +17,14 @@ SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="doc test"
 
-RDEPEND="dev-python/PyQt4
-	>=dev-python/pyinotify-0.7.1
+RDEPEND="
 	dev-python/jsonpickle
-	>=dev-vcs/git-1.6.3"
+	dev-python/pyinotify
+	dev-python/PyQt4
+	dev-vcs/git"
 DEPEND="${RDEPEND}
-	doc? ( app-text/asciidoc
+	doc? (
+		app-text/asciidoc
 		dev-python/sphinx
 		app-text/xmlto )
 	sys-devel/gettext
@@ -49,7 +51,7 @@ src_prepare() {
 	# don't prefix install path with homedir
 	rm setup.cfg
 
-	epatch "${FILESDIR}/1.3.8-disable-tests.patch"
+	epatch "${FILESDIR}"/1.3.8-disable-tests.patch
 
 	python_convert_shebangs 2 bin/git-cola share/git-cola/bin/ssh-askpass
 }
diff --git a/dev-vcs/cola/cola-1.4.3.3.ebuild b/dev-vcs/cola/cola-1.4.3.3.ebuild
new file mode 100644
index 000000000000..4e4019d2144f
--- /dev/null
+++ b/dev-vcs/cola/cola-1.4.3.3.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/cola/cola-1.4.3.3.ebuild,v 1.1 2011/04/23 07:05:25 jlec Exp $
+
+EAPI="3"
+
+PYTHON_DEPEND="2"
+
+inherit distutils eutils
+
+DESCRIPTION="A sweet, carbonated git gui known for its sugary flavour and caffeine-inspired features."
+HOMEPAGE="http://cola.tuxfamily.org/"
+SRC_URI="http://cola.tuxfamily.org/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/jsonpickle
+	dev-python/pyinotify
+	dev-python/PyQt4
+	dev-vcs/git"
+DEPEND="${RDEPEND}
+	doc? (
+		app-text/asciidoc
+		dev-python/sphinx
+		app-text/xmlto )
+	sys-devel/gettext
+	test? ( dev-python/nose )"
+
+# tests currently broken due to unfinished translation framework
+RESTRICT="test"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	# don't install docs into wrong location
+	sed -i \
+		-e '/doc/d' \
+		setup.py || die "sed failed"
+
+	sed -i \
+		-e  "s|'doc', 'git-cola'|'doc', '${PF}', 'html'|" \
+		cola/resources.py || die "sed failed"
+
+	# don't prefix install path with homedir
+	rm setup.cfg
+
+	epatch "${FILESDIR}"/1.3.8-disable-tests.patch
+
+	python_convert_shebangs 2 bin/git-cola share/git-cola/bin/ssh-askpass
+}
+
+src_compile() {
+	distutils_src_compile
+
+	if use doc ; then
+		cd share/doc/git-cola/
+		emake all || die "building docs failed"
+	fi
+}
+
+src_install() {
+	distutils_src_install
+
+	# remove bundled libraries
+	rm -rf "${D}"/usr/share/git-cola/lib/{jsonpickle,simplejson}
+
+	# remove wrong translation file
+	rm -rf "${D}/usr/share/locale/"
+
+	insinto /usr/share/locale
+	doins -r share/locale/*
+
+	cd share/doc/git-cola/
+	dodoc *.txt
+
+	if use doc ; then
+		dohtml -r _build/html/*
+		doman *.1
+	else
+		dohtml "${FILESDIR}/index.html"
+	fi
+}
+
+src_test() {
+	PYTHONPATH="${S}:${S}/build/lib:${PYTHONPATH}" LC_ALL="C" nosetests \
+		--verbose --with-doctest --with-id --exclude=jsonpickle --exclude=json \
+		|| die "running nosetests failed"
+}
+
+pkg_postinst() {
+	python_mod_optimize /usr/share/git-cola/lib/cola
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/share/git-cola/lib/cola
+}