Version bump.

(Portage version: 2.2.0_alpha114/cvs/Linux x86_64)

2 files changed, 73 insertions, 1 deletions

diff --git a/dev-ruby/aws-sdk/ChangeLog b/dev-ruby/aws-sdk/ChangeLog
index 7e1cbb516b12..0e5a607388e7 100644
--- a/dev-ruby/aws-sdk/ChangeLog
+++ b/dev-ruby/aws-sdk/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/aws-sdk
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/aws-sdk/ChangeLog,v 1.2 2012/06/27 10:43:37 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/aws-sdk/ChangeLog,v 1.3 2012/06/30 21:12:13 flameeyes Exp $
+
+*aws-sdk-1.5.6 (30 Jun 2012)
+
+  30 Jun 2012; Diego E. Pettenò <flameeyes@gentoo.org> +aws-sdk-1.5.6.ebuild:
+  Version bump.
 
 *aws-sdk-1.5.5 (27 Jun 2012)
 
diff --git a/dev-ruby/aws-sdk/aws-sdk-1.5.6.ebuild b/dev-ruby/aws-sdk/aws-sdk-1.5.6.ebuild
new file mode 100644
index 000000000000..acac42ff9845
--- /dev/null
+++ b/dev-ruby/aws-sdk/aws-sdk-1.5.6.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/aws-sdk/aws-sdk-1.5.6.ebuild,v 1.1 2012/06/30 21:12:13 flameeyes Exp $
+
+EAPI=4
+
+USE_RUBY="ruby18 ruby19 ree18"
+
+RUBY_FAKEGEM_TASK_TEST=""
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="README.rdoc"
+
+RUBY_FAKEGEM_EXTRAINSTALL="ca-bundle.crt"
+
+GITHUB_USER="amazonwebservices"
+GITHUB_PROJECT="${PN}-for-ruby"
+RUBY_S="${GITHUB_USER}-${GITHUB_PROJECT}-*"
+
+RUBY_FAKEGEM_GEMSPEC="${T}/${P}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Official SDK for Amazon Web Services"
+HOMEPAGE="http://aws.amazon.com/sdkforruby"
+SRC_URI="https://github.com/${GITHUB_USER}/${GITHUB_PROJECT}/tarball/${PV} -> ${GITHUB_PROJECT}-${PV}.tar.gz"
+
+LICENSE="APSL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+ruby_add_rdepend "virtual/ruby-ssl
+	>=dev-ruby/httparty-0.7
+	>=dev-ruby/json-1.4
+	>=dev-ruby/nokogiri-1.4.4
+	>=dev-ruby/uuidtools-2.1"
+ruby_add_bdepend "
+	test? ( dev-ruby/rspec )"
+
+all_ruby_prepare() {
+	rm Gemfile* || die
+
+	epatch "${FILESDIR}"/${PN}-1.5.3-disabletest.patch
+}
+
+all_ruby_compile() {
+	if use doc; then
+		rdoc || die
+	fi
+}
+
+each_ruby_test() {
+	${RUBY} -S rspec -Ilib -raws || die
+}
+
+each_ruby_install() {
+	sed -e "s:VERSION:${PV}:" "${FILESDIR}"/${PN}.gemspec > "${RUBY_FAKEGEM_GEMSPEC}"
+	each_fakegem_install
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	insinto /usr/share/doc/${PF}
+	doins -r recipebook samples
+}