Convert to distutils-r1.

(Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

3 files changed, 78 insertions, 49 deletions

diff --git a/dev-python/flask/ChangeLog b/dev-python/flask/ChangeLog
index b2aecccba274..cac9f19120d6 100644
--- a/dev-python/flask/ChangeLog
+++ b/dev-python/flask/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/flask
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v 1.16 2012/08/20 17:23:44 floppym Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v 1.17 2013/03/28 03:18:19 floppym Exp $
+
+*flask-0.9-r1 (28 Mar 2013)
+
+  28 Mar 2013; Mike Gilbert <floppym@gentoo.org> +flask-0.9-r1.ebuild,
+  flask-9999.ebuild:
+  Convert to distutils-r1.
 
   20 Aug 2012; Mike Gilbert <floppym@gentoo.org> flask-0.9.ebuild:
   Drop unused sed statement; applied upstream. Thanks to Arfrever.
diff --git a/dev-python/flask/flask-0.9-r1.ebuild b/dev-python/flask/flask-0.9-r1.ebuild
new file mode 100644
index 000000000000..972fbbde96a1
--- /dev/null
+++ b/dev-python/flask/flask-0.9-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/flask-0.9-r1.ebuild,v 1.1 2013/03/28 03:18:19 floppym Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy{1_9,2_0} )
+
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+HOMEPAGE="http://pypi.python.org/pypi/Flask"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+RDEPEND="dev-python/blinker[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.4[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.6.1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+python_test() {
+	"${PYTHON}" run-tests.py || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
diff --git a/dev-python/flask/flask-9999.ebuild b/dev-python/flask/flask-9999.ebuild
index 27321d7d7b2f..2729f5f64761 100644
--- a/dev-python/flask/flask-9999.ebuild
+++ b/dev-python/flask/flask-9999.ebuild
@@ -1,64 +1,48 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/flask-9999.ebuild,v 1.2 2012/04/10 13:01:00 rafaelmartins Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/flask-9999.ebuild,v 1.3 2013/03/28 03:18:18 floppym Exp $
 
-EAPI="3"
-PYTHON_DEPEND="2:2.5"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="2.4 3.*"
+EAPI="5"
+PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy{1_9,2_0} )
 
+inherit distutils-r1
+#if LIVE
+inherit git-2
 EGIT_REPO_URI="git://github.com/mitsuhiko/flask.git
 	https://github.com/mitsuhiko/flask.git"
-
-inherit distutils git-2
-
-MY_PN="Flask"
+#endif
 
 DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
 HOMEPAGE="http://pypi.python.org/pypi/Flask"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS=""
-IUSE="doc examples test"
-
-RDEPEND="dev-python/blinker
-	>=dev-python/jinja-2.4
-	dev-python/setuptools
-	>=dev-python/werkzeug-0.6.1"
-DEPEND="${RDEPEND}
-	doc? ( >=dev-python/sphinx-0.6 )"
-
-src_compile() {
-	distutils_src_compile
-
-	if use doc; then
-		einfo "Generation of documentation"
-		pushd docs > /dev/null
-		PYTHONPATH=".." emake html || die "Generation of documentation failed"
-		popd > /dev/null
-	fi
-}
-
-src_test() {
-	testing() {
-		PYTHONPATH="." "$(PYTHON)" run-tests.py
-	}
-	python_execute_function testing
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+RDEPEND="dev-python/blinker[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.4[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.6.1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+#if LIVE
+SRC_URI=
+KEYWORDS=
+#endif
+
+python_test() {
+	"${PYTHON}" run-tests.py || die "Testing failed with ${EPYTHON}"
 }
 
-src_install() {
-	distutils_src_install
-
-	if use doc; then
-		pushd docs/_build/html > /dev/null
-		insinto /usr/share/doc/${PF}/html
-		doins -r [a-z]* _images _static || die "Installation of documentation failed"
-		popd > /dev/null
-	fi
-
+python_install_all() {
 	if use examples; then
 		insinto /usr/share/doc/${PF}
-		doins -r examples || die "Installation of examples failed"
+		doins -r examples
+		docompress -x /usr/share/doc/${PF}/examples
 	fi
 }