Version bump. Migrate to distutils-r1.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 60 insertions, 2 deletions

diff --git a/dev-python/apsw/ChangeLog b/dev-python/apsw/ChangeLog
index 182e31859c14..ed3f9d670c54 100644
--- a/dev-python/apsw/ChangeLog
+++ b/dev-python/apsw/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/apsw
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/apsw/ChangeLog,v 1.54 2012/12/08 21:39:55 floppym Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/apsw/ChangeLog,v 1.55 2013/01/05 21:23:06 radhermit Exp $
+
+*apsw-3.7.15.1_p1 (05 Jan 2013)
+
+  05 Jan 2013; Tim Harder <radhermit@gentoo.org> +apsw-3.7.15.1_p1.ebuild:
+  Version bump. Migrate to distutils-r1.
 
   08 Dec 2012; Mike Gilbert <floppym@gentoo.org> apsw-3.7.14.1_p1.ebuild,
   apsw-3.7.14_p1.ebuild:
diff --git a/dev-python/apsw/apsw-3.7.15.1_p1.ebuild b/dev-python/apsw/apsw-3.7.15.1_p1.ebuild
new file mode 100644
index 000000000000..80c3bf0a7bc8
--- /dev/null
+++ b/dev-python/apsw/apsw-3.7.15.1_p1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/apsw/apsw-3.7.15.1_p1.ebuild,v 1.1 2013/01/05 21:23:06 radhermit Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2,3_3} )
+
+inherit distutils-r1
+
+MY_PV="${PV/_p/-r}"
+
+DESCRIPTION="APSW - Another Python SQLite Wrapper"
+HOMEPAGE="http://code.google.com/p/apsw/"
+SRC_URI="http://apsw.googlecode.com/files/${PN}-${MY_PV}.zip"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="doc"
+
+RDEPEND=">=dev-db/sqlite-${PV%_p*}[extensions]"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.6.20.1-fix_tests.patch )
+
+python_compile() {
+	if [[ ${EPYTHON} == python2* ]]; then
+		local CFLAGS="${CFLAGS} -fno-strict-aliasing"
+		export CFLAGS
+	fi
+	distutils-r1_python_compile --enable=load_extension
+}
+
+src_test() {
+	# tests use overlapping database files
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+	distutils-r1_src_test
+}
+
+python_test() {
+	"${PYTHON}" setup.py build_test_extension || die "Building of test loadable extension failed"
+	"${PYTHON}" tests.py -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use doc ; then
+		dohtml -r doc/*
+	fi
+}