Version bump, works perfectly with bluez-4.31.

(Portage version: 2.1.6.7/cvs/Linux x86_64)

2 files changed, 91 insertions, 2 deletions

diff --git a/app-mobilephone/obexftp/ChangeLog b/app-mobilephone/obexftp/ChangeLog
index 0e1b289be2a4..82db741ad58b 100644
--- a/app-mobilephone/obexftp/ChangeLog
+++ b/app-mobilephone/obexftp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-mobilephone/obexftp
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.44 2008/12/11 20:25:53 mrness Exp $
+# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.45 2009/02/28 00:02:28 dev-zero Exp $
+
+*obexftp-0.23 (28 Feb 2009)
+
+  28 Feb 2009; Tiziano Müller <dev-zero@gentoo.org> +obexftp-0.23.ebuild:
+  Version bump, works perfectly with bluez-4.31.
 
   11 Dec 2008; Alin Năstac <mrness@gentoo.org>
   +files/obexftp-0.22-bluetooth.patch, -obexftp-0.22_rc9.ebuild,
diff --git a/app-mobilephone/obexftp/obexftp-0.23.ebuild b/app-mobilephone/obexftp/obexftp-0.23.ebuild
new file mode 100644
index 000000000000..14fa5716f77a
--- /dev/null
+++ b/app-mobilephone/obexftp/obexftp-0.23.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/obexftp-0.23.ebuild,v 1.1 2009/02/28 00:02:28 dev-zero Exp $
+
+EAPI="2"
+
+inherit eutils perl-module flag-o-matic python
+
+DESCRIPTION="File transfer over OBEX for mobile phones"
+HOMEPAGE="http://dev.zuckschwerdt.org/openobex/wiki/ObexFtp"
+SRC_URI="mirror://sourceforge/openobex/${P}.tar.bz2"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
+IUSE="bluetooth debug perl python ruby swig tcl"
+
+RDEPEND="dev-libs/openobex
+	bluetooth? ( net-wireless/bluez )
+	perl? ( dev-lang/perl )
+	python? ( >=dev-lang/python-2.4.4 )
+	ruby? ( dev-lang/ruby )
+	tcl? ( dev-lang/tcl )"
+DEPEND="${RDEPEND}
+	swig? ( dev-lang/swig )
+	dev-util/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.22-ruby-libpath.patch"
+}
+
+src_configure() {
+	# do not byte-compile python module
+	if use python; then
+		sed -i \
+			-e 's/\(setup.py install\)/\1 --no-compile/' \
+			swig/python/Makefile.in || die "sed failed"
+	fi
+
+	if use debug ; then
+		strip-flags
+		append-flags "-g -DOBEXFTP_DEBUG=5"
+	fi
+
+	econf \
+		$(use_enable bluetooth) \
+		$(use_enable swig) \
+		$(use_enable perl) \
+		$(use_enable python) \
+		$(use_enable tcl) \
+		$(use_enable ruby) || die "econf failed"
+}
+
+src_install() {
+	# -j1 because "make -fMakefile.ruby install" fails
+	# upstream added -j1 to that command so it should be removed
+	# from here in the next version bump
+	emake -j1 DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS ChangeLog NEWS README* THANKS TODO
+	dohtml doc/*.html
+
+	# Install examples
+	insinto /usr/share/doc/${PF}/examples
+	doins examples/*.c
+	use perl && doins examples/*.pl
+	use python && doins examples/*.py
+	use ruby && doins examples/*.rb
+	use tcl && doins examples/*.tcl
+
+	use perl && fixlocalpod
+}
+
+pkg_postrm() {
+	use perl && perl-module_pkg_postrm
+	use python && python_mod_cleanup
+}
+
+pkg_postinst() {
+	use perl && perl-module_pkg_postinst
+	use python && {
+		python_version
+		python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/${PN}
+	}
+}