Version bump. Updated home page, doc building, added patch for underlinking cholmod

(Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

4 files changed, 120 insertions, 89 deletions

diff --git a/sci-libs/ceres-solver/ChangeLog b/sci-libs/ceres-solver/ChangeLog
index 0cff93daa551..3f17d6909391 100644
--- a/sci-libs/ceres-solver/ChangeLog
+++ b/sci-libs/ceres-solver/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for sci-libs/ceres-solver
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/ChangeLog,v 1.7 2013/11/14 01:49:00 bicatali Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/ChangeLog,v 1.8 2014/06/09 02:29:13 bicatali Exp $
+
+*ceres-solver-1.9.0 (09 Jun 2014)
+
+  09 Jun 2014; Sébastien Fabbro <bicatali@gentoo.org>
+  +ceres-solver-1.9.0.ebuild, +files/ceres-solver-1.9.0-underlink.patch,
+  -ceres-solver-1.7.0.ebuild:
+  Version bump. Updated home page, doc building, added patch for underlinking
+  cholmod
 
 *ceres-solver-1.8.0 (14 Nov 2013)
 
diff --git a/sci-libs/ceres-solver/ceres-solver-1.7.0.ebuild b/sci-libs/ceres-solver/ceres-solver-1.7.0.ebuild
deleted file mode 100644
index 5d27a1ac243b..000000000000
--- a/sci-libs/ceres-solver/ceres-solver-1.7.0.ebuild
+++ /dev/null
@@ -1,87 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/ceres-solver-1.7.0.ebuild,v 1.1 2013/10/23 18:36:55 bicatali Exp $
-
-EAPI=5
-
-inherit cmake-utils eutils multilib toolchain-funcs
-
-DESCRIPTION="Nonlinear least-squares minimizer"
-HOMEPAGE="https://code.google.com/p/ceres-solver/"
-SRC_URI="https://${PN}.googlecode.com/files/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="doc examples gflags metis openmp protobuf +schur +sparse static-libs test"
-REQUIRED_USE="test? ( gflags )"
-
-RDEPEND="
-	dev-cpp/eigen:3
-	dev-cpp/glog[gflags?]
-	protobuf? ( dev-libs/protobuf )
-	sparse? (
-		sci-libs/amd
-		sci-libs/camd
-		sci-libs/ccolamd
-		sci-libs/cholmod[metis?]
-		sci-libs/colamd
-		sci-libs/cxsparse
-		sci-libs/spqr
-		virtual/blas
-		virtual/lapack )"
-DEPEND="${RDEPEND}
-	sparse? ( virtual/pkgconfig )
-	doc? ( dev-python/sphinx )"
-
-src_prepare() {
-	# prefix love
-	# disable blas/lapack forced library names
-	sed -i \
-		-e "s:/usr:${EPREFIX}/usr:g" \
-		-e '/FIND_LIBRARY(BLAS_LIB NAMES blas)/d' \
-		-e '/FIND_LIBRARY(LAPACK_LIB NAMES lapack)/d' \
-		-e 's/EXISTS ${BLAS_LIB}/BLAS_LIB/g' \
-		-e 's/EXISTS ${LAPACK_LIB}/LAPACK_LIB/g' \
-		-e 's/-Werror//g' \
-		CMakeLists.txt || die
-
-	# respect gentoo doc dir
-	sed -i \
-		-e "s:share/doc/ceres:share/doc/${PF}:" \
-		docs/source/CMakeLists.txt || die
-}
-
-src_configure() {
-	local blibs llibs
-	if use sparse; then
-		blibs=$($(tc-getPKG_CONFIG) --libs blas)
-		llibs=$($(tc-getPKG_CONFIG) --libs lapack)
-	fi
-	local mycmakeargs=(
-		-DBLAS_LIB="${blibs}"
-		-DLAPACK_LIB="${llibs}"
-		$(cmake-utils_use_enable test TESTING)
-		$(cmake-utils_use doc BUILD_DOCUMENTATION)
-		$(cmake-utils_use gflags GFLAGS)
-		$(cmake-utils_use openmp OPENMP)
-		$(cmake-utils_use protobuf PROTOBUF)
-		$(cmake-utils_use schur SCHUR_SPECIALIZATIONS)
-		$(cmake-utils_use sparse CXSPARSE)
-		$(cmake-utils_use sparse SUITESPARSE)
-	)
-	cmake-utils_src_configure
-}
-
-src_install() {
-	cmake-utils_src_install
-	dodoc README VERSION
-
-	use static-libs || rm "${ED}"/usr/$(get_libdir)/libceres.a
-	dosym libceres_shared.so /usr/$(get_libdir)/libceres.so
-
-	if use examples; then
-		insinto /usr/share/doc/${PF}
-		doins -r examples
-	fi
-}
diff --git a/sci-libs/ceres-solver/ceres-solver-1.9.0.ebuild b/sci-libs/ceres-solver/ceres-solver-1.9.0.ebuild
new file mode 100644
index 000000000000..aeb6612761ba
--- /dev/null
+++ b/sci-libs/ceres-solver/ceres-solver-1.9.0.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/ceres-solver/ceres-solver-1.9.0.ebuild,v 1.1 2014/06/09 02:29:13 bicatali Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit cmake-utils eutils multilib python-any-r1 toolchain-funcs
+
+DESCRIPTION="Nonlinear least-squares minimizer"
+HOMEPAGE="http://ceres-solver.org/"
+SRC_URI="${HOMEPAGE}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="cxsparse doc examples gflags lapack openmp protobuf +schur sparse static-libs test"
+REQUIRED_USE="test? ( gflags ) sparse? ( lapack ) doc? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-cpp/glog[gflags?]
+	cxsparse? ( sci-libs/cxsparse:0= )
+	lapack? ( virtual/lapack )
+	protobuf? ( dev-libs/protobuf )
+	sparse? (
+		sci-libs/amd:0=
+		sci-libs/camd:0=
+		sci-libs/ccolamd:0=
+		sci-libs/cholmod:0=
+		sci-libs/colamd:0=
+		sci-libs/spqr:0= )"
+
+DEPEND="${RDEPEND}
+	dev-cpp/eigen:3
+	doc? ( dev-python/sphinx dev-python/sphinx_rtd_theme )
+	lapack? ( virtual/pkgconfig )"
+
+PATCHES=( "${FILESDIR}"/${P}-underlink.patch )
+
+pkg_setup() {
+	# XXX: this looks like it should be used with BUILD_TYPE!=binary
+	if use openmp; then
+		if [[ $(tc-getCXX) == *g++* ]] && ! tc-has-openmp; then
+			ewarn "OpenMP is not available in your current selected gcc"
+			die "need openmp capable gcc"
+		fi
+	fi
+	use doc && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# search paths work for prefix
+	sed -i \
+		-e "s:/usr:${EPREFIX}/usr:g" \
+		cmake/*.cmake || die
+
+	# remove Werror
+	sed -i \
+		-e 's/-Werror//g' \
+		CMakeLists.txt || die
+
+	# respect gentoo doc install directory
+	sed -i \
+		-e "s:share/doc/ceres:share/doc/${PF}:" \
+		docs/source/CMakeLists.txt || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_EXAMPLES=OFF
+		$(cmake-utils_use_enable test TESTING)
+		$(cmake-utils_use doc BUILD_DOCUMENTATION)
+		$(cmake-utils_use gflags GFLAGS)
+		$(cmake-utils_use lapack LAPACK)
+		$(cmake-utils_use openmp OPENMP)
+		$(cmake-utils_use protobuf PROTOBUF)
+		$(cmake-utils_use schur SCHUR_SPECIALIZATIONS)
+		$(cmake-utils_use cxsparse CXSPARSE)
+		$(cmake-utils_use sparse SUITESPARSE)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	dodoc README VERSION
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		docompress -x /usr/share/doc/${PF}/examples
+		doins -r examples data
+	fi
+}
diff --git a/sci-libs/ceres-solver/files/ceres-solver-1.9.0-underlink.patch b/sci-libs/ceres-solver/files/ceres-solver-1.9.0-underlink.patch
new file mode 100644
index 000000000000..00b005431687
--- /dev/null
+++ b/sci-libs/ceres-solver/files/ceres-solver-1.9.0-underlink.patch
@@ -0,0 +1,13 @@
+--- internal/ceres/CMakeLists.txt.orig	2014-06-05 08:45:55.031448944 -0700
++++ internal/ceres/CMakeLists.txt	2014-06-05 08:48:03.496344301 -0700
+@@ -146,8 +146,9 @@
+ 
+ SET(CERES_LIBRARY_PUBLIC_DEPENDENCIES ${GLOG_LIBRARIES})
+ 
+-IF (SUITESPARSE AND SUITESPARSE_FOUND)
++IF (SUITESPARSE AND SUITESPARSE_FOUND)
+   LIST(APPEND CERES_LIBRARY_PRIVATE_DEPENDENCIES ${SUITESPARSE_LIBRARIES})
++  LIST(APPEND CERES_LIBRARY_PUBLIC_DEPENDENCIES ${SUITESPARSE_LIBRARIES})
+ ENDIF (SUITESPARSE AND SUITESPARSE_FOUND)
+ 
+ IF (CXSPARSE AND CXSPARSE_FOUND)