From 2ca2dcec4f3c13c627e2a49ca1edb82254240dfd Mon Sep 17 00:00:00 2001
From: Ian Stakenvicius <axs@gentoo.org>
Date: Tue, 11 Oct 2016 16:22:03 -0400
Subject: x11-themes/greybird: generate the gtk3 theme using sass

Upstream converted ot using SASS to generate theme files in a manner
similar to Adwaita; a diff of the installed files with generation and
without showed there were small differences on 3.20.1, so the
3.20.1 and live (9999) versions are converted to use the autotools
build system.

Package-Manager: portage-2.3.0
---
 x11-themes/greybird/greybird-3.20.1-r1.ebuild | 44 ++++++++++++++++++++++++
 x11-themes/greybird/greybird-3.20.1.ebuild    | 48 ---------------------------
 x11-themes/greybird/greybird-9999.ebuild      | 32 ++++++++----------
 3 files changed, 57 insertions(+), 67 deletions(-)
 create mode 100644 x11-themes/greybird/greybird-3.20.1-r1.ebuild
 delete mode 100644 x11-themes/greybird/greybird-3.20.1.ebuild

(limited to 'x11-themes')

diff --git a/x11-themes/greybird/greybird-3.20.1-r1.ebuild b/x11-themes/greybird/greybird-3.20.1-r1.ebuild
new file mode 100644
index 000000000000..b8093ce376d4
--- /dev/null
+++ b/x11-themes/greybird/greybird-3.20.1-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools
+
+MY_PN=${PN/g/G}
+
+DESCRIPTION="The default theme from Xubuntu"
+HOMEPAGE="http://shimmerproject.org/project/greybird/ https://github.com/shimmerproject/Greybird"
+SRC_URI="https://github.com/shimmerproject/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+# README says "dual-licensed as GPLv2 or later and CC-BY-SA 3.0 or later"
+LICENSE="CC-BY-SA-3.0 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="ayatana gnome"
+
+RDEPEND="
+	>=x11-themes/gtk-engines-murrine-0.90
+	>=x11-libs/gtk+-3.20.0
+"
+DEPEND="${RDEPEND}
+	dev-ruby/sass
+	dev-libs/glib:2
+"
+
+S=${WORKDIR}/${MY_PN}-${PV}
+#RESTRICT="binchecks strip"
+
+src_prepare() {
+	eapply_user
+	eautoreconf
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	pushd "${ED}"usr/share/themes/${MY_PN} > /dev/null || die
+	use ayatana || rm -rf unity
+	use gnome || rm -rf metacity-1
+	popd > /dev/null || die
+}
diff --git a/x11-themes/greybird/greybird-3.20.1.ebuild b/x11-themes/greybird/greybird-3.20.1.ebuild
deleted file mode 100644
index 44410f098694..000000000000
--- a/x11-themes/greybird/greybird-3.20.1.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=6
-
-MY_PN=${PN/g/G}
-
-DESCRIPTION="The default theme from Xubuntu"
-HOMEPAGE="http://shimmerproject.org/project/greybird/ https://github.com/shimmerproject/Greybird"
-SRC_URI="https://github.com/shimmerproject/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-# README says "dual-licensed as GPLv2 or later and CC-BY-SA 3.0 or later"
-LICENSE="CC-BY-SA-3.0 GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
-IUSE="ayatana gnome"
-
-RDEPEND="
-	>=x11-themes/gtk-engines-murrine-0.90
-"
-
-RESTRICT="binchecks strip"
-
-S=${WORKDIR}/${MY_PN}-${PV}
-
-src_install() {
-	dodoc README.md
-	rm -f README.md configure.ac autogen.sh Makefile.am LICENSE*
-
-	insinto /usr/share/themes/${MY_PN}-compact/xfwm4
-	doins xfwm4-compact/*
-	rm -rf xfwm4-compact
-
-	insinto /usr/share/themes/${MY_PN}-a11y/xfwm4
-	doins xfwm4-a11y/*
-	rm -rf xfwm4-a11y
-
-	insinto /usr/share/themes/${MY_PN}-bright/xfce-notify-4.0
-	doins xfce-notify-4.0_bright/*
-	rm -rf xfce-notify-4.0_bright
-
-	use ayatana || rm -rf unity
-	use gnome || rm -rf metacity-1
-
-	insinto /usr/share/themes/${MY_PN}
-	doins -r *
-}
diff --git a/x11-themes/greybird/greybird-9999.ebuild b/x11-themes/greybird/greybird-9999.ebuild
index 4a05a61fd92c..dd25b51b02b0 100644
--- a/x11-themes/greybird/greybird-9999.ebuild
+++ b/x11-themes/greybird/greybird-9999.ebuild
@@ -3,7 +3,7 @@
 # $Id$
 
 EAPI=6
-inherit git-r3
+inherit autotools git-r3
 
 MY_PN=${PN/g/G}
 
@@ -19,29 +19,23 @@ IUSE="ayatana gnome"
 
 RDEPEND="
 	>=x11-themes/gtk-engines-murrine-0.90
+	>=x11-libs/gtk+-3.20.0
+"
+DEPEND="${RDEPEND}
+	dev-ruby/sass
+	dev-libs/glib:2
 "
 
-RESTRICT="binchecks strip"
+src_prepare() {
+	eapply_user
+	eautoreconf
+}
 
 src_install() {
-	dodoc README.md
-	rm -f README.md configure.ac autogen.sh Makefile.am LICENSE*
-
-	insinto /usr/share/themes/${MY_PN}-compact/xfwm4
-	doins xfwm4-compact/*
-	rm -rf xfwm4-compact
-
-	insinto /usr/share/themes/${MY_PN}-a11y/xfwm4
-	doins xfwm4-a11y/*
-	rm -rf xfwm4-a11y
-
-	insinto /usr/share/themes/${MY_PN}-bright/xfce-notify-4.0
-	doins xfce-notify-4.0_bright/*
-	rm -rf xfce-notify-4.0_bright
+	emake DESTDIR="${D}" install
 
+	pushd "${ED}"usr/share/themes/${MY_PN} > /dev/null || die
 	use ayatana || rm -rf unity
 	use gnome || rm -rf metacity-1
-
-	insinto /usr/share/themes/${MY_PN}
-	doins -r *
+	popd > /dev/null || die
 }
-- 
cgit v1.2.3-65-gdbad