From f8b349d69cea2134a9b0b5ecb87e8e283f3cc1f0 Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Fri, 12 Jun 2020 14:22:13 +0200
Subject: dev-ruby/net-ssh: add missing dependency

Add missing dev-ruby/x25519 dependency. Drop arm ppc ppc64 x86 keywords,
bug 728064

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Hans de Graaff <graaff@gentoo.org>
---
 dev-ruby/net-ssh/net-ssh-6.1.0-r1.ebuild | 44 ++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 dev-ruby/net-ssh/net-ssh-6.1.0-r1.ebuild

(limited to 'dev-ruby/net-ssh')

diff --git a/dev-ruby/net-ssh/net-ssh-6.1.0-r1.ebuild b/dev-ruby/net-ssh/net-ssh-6.1.0-r1.ebuild
new file mode 100644
index 000000000000..e99cacb26708
--- /dev/null
+++ b/dev-ruby/net-ssh/net-ssh-6.1.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby24 ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGES.txt README.md THANKS.txt"
+RUBY_FAKEGEM_EXTRAINSTALL="support"
+
+RUBY_FAKEGEM_GEMSPEC="net-ssh.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Non-interactive SSH processing in pure Ruby"
+HOMEPAGE="https://github.com/net-ssh/net-ssh"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> net-ssh-git-${PV}.tgz"
+
+LICENSE="GPL-2"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64"
+IUSE="ed25519 test"
+
+ruby_add_rdepend "virtual/ruby-ssl ed25519? ( >=dev-ruby/ed25519-1.2:1 dev-ruby/x25519 dev-ruby/bcrypt_pbkdf:1 )"
+ruby_add_bdepend "test? ( dev-ruby/test-unit:2 >=dev-ruby/mocha-0.13 )"
+
+all_ruby_prepare() {
+	# Avoid bundler dependency
+	sed -i -e '/\(bundler\|:release\)/ s:^:#:' Rakefile || die
+
+	sed -e "s:require_relative ':require './:" \
+		-e 's/git ls-files -z/find -print0/' \
+		-i ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+src_test() {
+	# prevent tests from trying to connect to ssh-agent socket and failing
+	unset SSH_AUTH_SOCK
+	if ! use ed25519; then
+		export NET_SSH_NO_ED25519=true
+	fi
+	ruby-ng_src_test
+}
-- 
cgit v1.2.3-65-gdbad