From 34e7d0b4266fec1978becc21bf02d8ff798e17da Mon Sep 17 00:00:00 2001
From: Ben Kohler <bkohler@gentoo.org>
Date: Thu, 5 Dec 2019 15:01:34 -0600
Subject: dev-python/paver: add missing six dep, and add python3_7

Package-Manager: Portage-2.3.80, Repoman-2.3.19
Signed-off-by: Ben Kohler <bkohler@gentoo.org>
---
 dev-python/paver/paver-1.3.4-r1.ebuild | 42 ++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 dev-python/paver/paver-1.3.4-r1.ebuild

(limited to 'dev-python/paver')

diff --git a/dev-python/paver/paver-1.3.4-r1.ebuild b/dev-python/paver/paver-1.3.4-r1.ebuild
new file mode 100644
index 000000000000..7dfbcd902d82
--- /dev/null
+++ b/dev-python/paver/paver-1.3.4-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} pypy )
+
+inherit distutils-r1
+
+MY_PN=${PN/p/P}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python-based software project scripting tool along the lines of Make"
+HOMEPAGE="http://www.blueskyonmars.com/projects/paver/ https://github.com/paver/paver"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos ~x86-macos"
+IUSE="test"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# https://github.com/paver/paver/issues/143#issuecomment-103943327
+	find paver/tests -name '*.pyc' -delete || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests || die "Testing failed with ${EPYTHON}"
+}
-- 
cgit v1.2.3-65-gdbad