From d9e582fc1607bba035ffae4bbb95575fa91edcb7 Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Sun, 10 Jan 2021 17:58:19 -0500
Subject: dev-cpp/glibmm: Version bump to 2.68.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 dev-cpp/glibmm/Manifest             |  1 +
 dev-cpp/glibmm/glibmm-2.68.0.ebuild | 64 +++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)
 create mode 100644 dev-cpp/glibmm/glibmm-2.68.0.ebuild

(limited to 'dev-cpp/glibmm')

diff --git a/dev-cpp/glibmm/Manifest b/dev-cpp/glibmm/Manifest
index 61a2c01c66d4..a6ee6004d98f 100644
--- a/dev-cpp/glibmm/Manifest
+++ b/dev-cpp/glibmm/Manifest
@@ -1 +1,2 @@
 DIST glibmm-2.64.2.tar.xz 7438116 BLAKE2B 6ff458e90a5dbc606a2e04ecd3589262a1b96e827dba245985467818a7a4ba80a9c4cb15686fe479636cb8ce7e1db3334195d6334d7ec56327076cad87e22170 SHA512 0130af9a16981a54630150db6f4b1a95458d72d650c5e4781ee97ce624ec98c600b79ebf234d212e025781453fd11d78b9e8273235ffa143397423418fe970cc
+DIST glibmm-2.68.0.tar.xz 7652260 BLAKE2B df87b3f3d8cd74b693f843dec15d5376f2a755b0a72042983383c15cca9fdb90c2fed6320bf0f3fe846fcda5be3ee15c0fc1b683d29cebe64e8dcdd101fc9bf0 SHA512 a13121052315e949acf2528e226079f1a2cf7853080aec770dcb269e422997e5515ed767c7a549231fb3fa5f913b3fd9ef083080589283824b6a218d066b253e
diff --git a/dev-cpp/glibmm/glibmm-2.68.0.ebuild b/dev-cpp/glibmm/glibmm-2.68.0.ebuild
new file mode 100644
index 000000000000..ca0f9ed0f39c
--- /dev/null
+++ b/dev-cpp/glibmm/glibmm-2.68.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org meson multilib-minimal
+
+DESCRIPTION="C++ interface for glib2"
+HOMEPAGE="https://www.gtkmm.org"
+
+LICENSE="LGPL-2.1+"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris ~x86-solaris"
+IUSE="doc debug test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/libsigc++:3[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.63.0:2[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	sys-devel/m4
+	dev-lang/perl
+	doc? (
+		app-doc/doxygen
+		dev-libs/libxslt
+		media-gfx/graphviz
+	)
+"
+
+src_prepare() {
+	default
+
+	# giomm_tls_client requires FEATURES=-network-sandbox and glib-networking rdep
+	sed -i -e '/giomm_tls_client/d' tests/meson.build || die
+
+	if ! use test; then
+		sed -i -e "/^subdir('tests')/d" meson.build || die
+	fi
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dwarnings=min
+		-Dbuild-deprecated-api=true
+		-Dbuild-documentation=$(usex doc true false)
+		-Ddebug-refcounting=$(usex debug true false)
+		-Dbuild-examples=false
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_test() {
+	meson_src_test
+}
+
+multilib_src_install() {
+	meson_src_install
+}
-- 
cgit v1.2.3-65-gdbad