2 files changed, 53 insertions, 0 deletions
diff --git a/dev-python/python3-xapp/Manifest b/dev-python/python3-xapp/Manifest
index af943fdc5846..ff10cf341c24 100644
--- a/dev-python/python3-xapp/Manifest
+++ b/dev-python/python3-xapp/Manifest
@@ -1 +1,2 @@
 DIST python3-xapp-2.4.1.tar.gz 21181 BLAKE2B 460aba09d147d64c8102f66d059c6ab1f7c39893ce98844e59ab5954b690d81ab4b253cb6a17f9b3c781dfb5e965d1a4de859aaeff5ef65ab3f67a86a4c6e6c2 SHA512 97045061aa5965adcfe7301774dbd35a226fa9b846e31a7c097229cc417ff4008e518ebd5b600d4ce6a46daa39d51de70d391b6b0a7c78490419d3a96daca6a9
+DIST python3-xapp-2.4.2.tar.gz 21482 BLAKE2B bacea6a626efa8ee60a4f91923e48e0e9e49d08ca0c9a5998b724284edc353912099f2deafc6eb7cf6a42a983f97f8cc03fe86c18338c89823f103e413685637 SHA512 04f995986eabaf613d166ae31bd36eda2b3563ea58aded64b132940430db9d59f9525eb562b0ad8d7649844adbaf28332c4f51fa633610b102feae97bc1bfc9f
diff --git a/dev-python/python3-xapp/python3-xapp-2.4.2.ebuild b/dev-python/python3-xapp/python3-xapp-2.4.2.ebuild
new file mode 100644
index 000000000000..b6181624fc4e
--- /dev/null
+++ b/dev-python/python3-xapp/python3-xapp-2.4.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson python-r1
+
+DESCRIPTION="Python bindings for x11-libs/xapp"
+HOMEPAGE="https://github.com/linuxmint/python3-xapp"
+SRC_URI="https://github.com/linuxmint/python3-xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	$(python_gen_cond_dep '
+		>=x11-libs/xapp-2.8.4[introspection,${PYTHON_USEDEP}]
+	')
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+	dev-python/psutil[${PYTHON_USEDEP}]
+"
+
+src_configure() {
+	configuring() {
+		meson_src_configure \
+			-Dpython_target="${EPYTHON}"
+	}
+	python_foreach_impl configuring
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_test() {
+	python_foreach_impl meson_src_test
+}
+
+src_install() {
+	installing() {
+		meson_src_install
+		python_optimize
+	}
+	python_foreach_impl installing
+}