x11-terms/st: add 0.9

Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/x11-terms/st/Manifest b/x11-terms/st/Manifest
index ca6a601ac798..6451e88eb2fc 100644
--- a/x11-terms/st/Manifest
+++ b/x11-terms/st/Manifest
@@ -1,2 +1,3 @@
 DIST st-0.8.4.tar.gz 47330 BLAKE2B 709278a669414d7d44beba02ebb606853dbaa9cfe71650e40a11d3691d6bee2c0b2e8db57ca2df52776ca564a20f64f3ef7acec8dbad6d66408d314fe26fb794 SHA512 f6f95081f9d09d442228bac1149d75d36a9f4f049b5504cf5ce00b353563ff92c62a2628ce728663fec107a14bea0eeb22b7a72804c37090de33819243d7512a
 DIST st-0.8.5.tar.gz 47829 BLAKE2B 9c036b39605dcc69c03fd5a67e911545eb41e3e748efbcf4761770b2a9bf9f158fc1da1fc140b84fb9939fcb35ce126de444cd567806c350e8e2905907bdf645 SHA512 45cc51f9fc343bd80a48f23f5b00e41e0cc01a538474e0578dd02f02ce92cb560e0e7464ec47fd7de4d39483b23fda212c3e7c64233e8a3f4ab6862144d76323
+DIST st-0.9.tar.gz 48171 BLAKE2B f6713b565b785549a571b3775346351c6db79dfbb1a93e29aadd722f30e957e9f77d1644b150cd11f0993dec5accad9d825e6d6b380b4c84c5f526b6589d1b15 SHA512 8d996a68d55c63d84da9962911b076ef437842e8cd83d74672d95531dfbaea91e049430886459a99e859ec760bb3754e94bbe1f646410998725e5a8997fb70ea
diff --git a/x11-terms/st/st-0.9.ebuild b/x11-terms/st/st-0.9.ebuild
new file mode 100644
index 000000000000..a54b97850eb9
--- /dev/null
+++ b/x11-terms/st/st-0.9.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop savedconfig toolchain-funcs
+
+DESCRIPTION="Simple terminal implementation for X"
+HOMEPAGE="https://st.suckless.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.suckless.org/${PN}"
+else
+	SRC_URI="https://dl.suckless.org/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~m68k ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+
+RDEPEND="
+	>=sys-libs/ncurses-6.0:0=
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+	~x11-terms/st-terminfo-${PV}
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
+		-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
+		-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
+		config.mk || die
+	sed -i \
+		-e '/tic/d' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_configure() {
+	sed -i \
+		-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
+		config.mk || die
+
+	tc-export CC
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+
+	dodoc TODO
+
+	make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	if ! [[ "${REPLACING_VERSIONS}" ]]; then
+		elog "Please ensure a usable font is installed, like"
+		elog "    media-fonts/corefonts"
+		elog "    media-fonts/dejavu"
+		elog "    media-fonts/urw-fonts"
+	fi
+}