sys-kernel/gentoo-kernel-bin: add 5.10.64-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index feff7759f608..158aa4fbbd48 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -39,6 +39,7 @@ DIST gentoo-kernel-5.10.63-1.amd64.xpak 65513582 BLAKE2B acc38d0b51562dc75fcc23f
 DIST gentoo-kernel-5.10.63-1.arm64.xpak 61285352 BLAKE2B f883202b6dac80f8cd519bf71fb62fe7112b62ea48159ede8d229bb105d28521afdfea6b66bcd097ccaeb275d00324d842aea28d11ccf9113084e42684b8f794 SHA512 a27abbc2d8e887792c7fb5878e9253c0e60423190b386e32ea30ffd56a56dc11ed24c5ee0167042724fb10b34f577b4fc9691bfc521fed57ba23a8b007fcfa41
 DIST gentoo-kernel-5.10.63-1.x86.xpak 57245275 BLAKE2B 8b6632fd366ad93ef659daf85838c0a5d4144b12c365fc039b6d799898650edf05c63e3bc481b8440ef04c9a85dce7cc99b28b31312fe0872097c2e3d353ad66 SHA512 c54918c4a372fecdacef64ce2735f649e3ad154ad641bdd55be9bcf2bc67bbcd6f0c4fd2b496da99ae40e2bdf48cb1c4feac54e5c647b15bbac01565024519ec
 DIST gentoo-kernel-5.10.64-1.amd64.xpak 65498947 BLAKE2B cfad6efd8460bc60fd0caefbd3c5afe59484ab24e53840567769be97cee868f1a387144268bd87ab1f4d1ec9ecc3cd87ba190a5fd7a0702c71e38dd3e5de489f SHA512 381c177a4b39a2ec03baaaefb9b59edb46ca8e74a52aea93b59aa8c58611a78c91a192dfaea7aab365d2895aa2e19791ee6e68f4ac3c6ffd5eb2a9deb8f1c0a4
+DIST gentoo-kernel-5.10.64-1.arm64.xpak 61239142 BLAKE2B 32abfe4007ef3653a203160236cb5354f6168e8c28f28fad6e8a3c03b3fa0a205ebfcc94b8a839b80a7357284e15ffbfcc8fbd27c946c54acfbf7a17d2b09436 SHA512 0b9965ad49b39a7ee86ececa81a38be8ebb90eece0ef1f289bbccd28e47d9e465821f6274cf9a2736a74b76836e9499d23bd60920cd16be7bb8142c51b899967
 DIST gentoo-kernel-5.10.64-1.x86.xpak 57233627 BLAKE2B 0c7253729bd26e4e47821b5ed81dd696fb7a714d4f2613dae829b04e9dd7b4986c9a92c388e07e2628e74c50a20369ac92bf5b188d4933d3990f51e726305570 SHA512 d73cec3ef255a5338a9aea29daaae626619a1d33cb00a8b28c1b1aac17b5a4b48221c606be1320ec5f4b6851aa2fd8566281e69fc8aa7eea3e2eb89b1dd2ddfe
 DIST gentoo-kernel-5.12.19-1.amd64.xpak 66346655 BLAKE2B a03cbcdcd1a90d48d7e11e988d03efa43980f4d5d8af4b74e4c81f195faa01803af45fb38f7dc1f5af7e9b5338a53bc6f34837c37f7e853c088ec6c1dc084e44 SHA512 3d7f78c488ecee2532f8a8ad61e3aa0f5e238e4cd520d29288715a3dc5c488670d7378f3dc5bc110252dff10108dfbda27a54722c6b044151999428d002b34e1
 DIST gentoo-kernel-5.12.19-1.arm64.xpak 60043529 BLAKE2B 8746081847a39e1847b8e9f35fcd68565370b116d6418edf803c4cdca9d750ac8ada58c4a7fd377480a1c75b3c805864d419c02ee21675bc77ac195731385a18 SHA512 d1a8a9210a1ab3d3c1894be1fe524e64b859b0a02763feacfed1a24655540ade6c28af751b23e924fcc04fb9abd56e84c43d634ad80bbb4d5de79ed533b5ea50
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.64-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.64-r1.ebuild
new file mode 100644
index 000000000000..9f8ae493e215
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.64-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}