media-sound/ncmpc: bump to 0.49

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/media-sound/ncmpc/Manifest b/media-sound/ncmpc/Manifest
index 0ff059364f1a..b7fcdcac2904 100644
--- a/media-sound/ncmpc/Manifest
+++ b/media-sound/ncmpc/Manifest
@@ -1 +1,2 @@
 DIST ncmpc-0.48.tar.xz 296320 BLAKE2B ee25298af9d50eff646d74aa8908358a3df7b5ca7cf0666b6d3d31027e66d1219c2a48c5097e160d728db2965e2113a0915accac0d97f246d6e75152a2c9a1b3 SHA512 71739fefe696402d4a594a0c931bae0d6fc26f2b7203c51b3d6664c703276ad55f32ea247e1100224a3072386b6de067c1c2e43aa8b6cfac564f7f215ec11f7b
+DIST ncmpc-0.49.tar.xz 296012 BLAKE2B c87c07bcf107e20224982a99fdedb09468ed510f7e6138e6e35386c636bdf62a3fd79e609670f7931966e3be09de668d1119ade950f2b8e4cd7c546d47a405be SHA512 9913f08d90b229af59c8da0ac737445661dc69f0174f996dedbd0c9d9c4833004dbd9319f6bc08dc8b35a191ae167c090a3f31b43167e1918c5fad8f044a4c17
diff --git a/media-sound/ncmpc/ncmpc-0.49.ebuild b/media-sound/ncmpc/ncmpc-0.49.ebuild
new file mode 100644
index 000000000000..3b96020c8c58
--- /dev/null
+++ b/media-sound/ncmpc/ncmpc-0.49.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Ncurses client for the Music Player Daemon (MPD)"
+HOMEPAGE="https://www.musicpd.org/clients/ncmpc/ https://github.com/MusicPlayerDaemon/ncmpc"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="async-connect chat-screen doc +help-screen key-screen +library-screen lirc lyrics-screen +mouse nls outputs-screen pcre search-screen +song-screen test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )
+"
+RDEPEND="
+	media-libs/libmpdclient
+	sys-libs/ncurses:=[unicode(+)]
+	lirc? ( app-misc/lirc )
+	pcre? ( dev-libs/libpcre2 )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# use correct docdir and don't install license file
+	sed -e "/^docdir =/s/meson.project_name()/'${PF}'/" \
+		-e "s/'COPYING', //" \
+		-i meson.build || die
+
+	# use correct (html) docdir
+	sed -e "/install_dir:.*doc/s/meson.project_name()/'${PF}'/" \
+		-i doc/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcurses=ncursesw
+		-Dcolors=true
+		-Dmini=false
+		-Dlyrics_plugin_dir="${EPREFIX}/usr/$(get_libdir)/ncmpc/lyrics"
+		-Dasync_connect=$(usex async-connect true false)
+		-Dchat_screen=$(usex chat-screen true false)
+		-Ddocumentation=$(usex doc enabled disabled)
+		-Dhelp_screen=$(usex help-screen true false)
+		-Dkey_screen=$(usex key-screen true false)
+		-Dlibrary_screen=$(usex library-screen true false)
+		-Dlirc=$(usex lirc enabled disabled)
+		-Dlocale=$(usex nls enabled disabled)
+		-Dlyrics_screen=$(usex lyrics-screen true false)
+		-Dmouse=$(usex mouse enabled disabled)
+		-Dmultibyte=$(usex nls true false)
+		-Dnls=$(usex nls enabled disabled)
+		-Doutputs_screen=$(usex outputs-screen true false)
+		-Dregex=$(usex pcre enabled disabled)
+		-Dsearch_screen=$(usex search-screen true false)
+		-Dsong_screen=$(usex song-screen true false)
+		$(meson_use test)
+	)
+
+	meson_src_configure
+}