gnome-extra/gnome-software: 3.22.7 → 3.28.2

Switched build system to meson. Re-order dependencies according to
build-system. Enable fwupd support through USE=firmware.

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Gilles Dartiguelongue <eva@gentoo.org>

3 files changed, 104 insertions, 4 deletions

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index eced852ac4f1..75552fe0c0db 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1 +1,2 @@
 DIST gnome-software-3.22.7.tar.xz 3865764 BLAKE2B c23e3b9e34a9b233a584a920fcd5969b3ebb5fa4227da147870e71c1531da6c3efda913149a903667ae1725c505c1c842aac0a76b439a2730bf6c837f39757fc SHA512 184714710695d8c48451c1ee7885524dfa30cc6091975bdd317bdd6ce130e7815ab7474074ed191913594bcd5142932bd7918ae19a695170a34a5f934e1b9825
+DIST gnome-software-3.28.2.tar.xz 5181868 BLAKE2B 4744ff13216ac1421700ef9c5ec9fb540ffb527ed8bff1bd2f7b90cb5c9b768180e3b30fc0b44724e27479f56f8867551b4b19a9496664418a6b6cbe0960623e SHA512 ca22ea589c19f3c5aae32fb2540646d3b3c8faf86f857dd414caf61b716bc50dea16281955c594a629f684da5ac87eeada6ac68247a9b0545600b739fa436dd7
diff --git a/gnome-extra/gnome-software/gnome-software-3.28.2.ebuild b/gnome-extra/gnome-software/gnome-software-3.28.2.ebuild
new file mode 100644
index 000000000000..3556c78411ba
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-3.28.2.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome.org gnome2-utils meson python-any-r1 virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="firmware gnome gtk-doc spell test udev"
+
+RDEPEND="
+	>=dev-libs/appstream-glib-0.7.3:0
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/glib-2.46:2
+	>=x11-libs/gtk+-3.22.4:3
+	>=dev-libs/json-glib-1.2.0
+	app-crypt/libsecret
+	>=net-libs/libsoup-2.52.0:2.4
+	dev-db/sqlite:3
+	gnome? ( >=gnome-base/gnome-desktop-3.17.92:3= )
+	spell? ( app-text/gspell )
+	sys-auth/polkit
+	>=app-admin/packagekit-base-1.1.0
+	firmware? ( >=sys-apps/fwupd-1.0.3 )
+	udev? ( virtual/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+	dev-libs/libxml2:2
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+# test? ( dev-util/valgrind )
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# FIXME: investigate limba support
+	local emesonargs=(
+		$(meson_use test enable-tests)
+		$(meson_use spell enable-gspell)
+		$(meson_use gnome enable-gnome-desktop)
+		-Denable-man=true
+		-Denable-packagekit=true
+		-Denable-polkit=true
+		$(meson_use firmware enable-fwupd)
+		-Denable-flatpak=false
+		-Denable-limba=false
+		-Denable-rpm-ostree=false
+		-Denable-steam=false
+		$(meson_use gnome enable-shell-extensions)
+		-Denable-odrs=false
+		-Denable-ubuntuone=false
+		-Denable-ubuntu-reviews=false
+		-Denable-webapps=true
+		$(meson_use udev enable-gudev)
+		-Denable-snap=false
+		-Denable-external-appstream=false
+		-Denable-valgrind=false
+		$(meson_use gtk-doc enable-gtk-doc)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+	GSETTINGS_SCHEMA_DIR="${S}/data" virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+	gnome2_icon_cache_update
+}
diff --git a/gnome-extra/gnome-software/metadata.xml b/gnome-extra/gnome-software/metadata.xml
index 4cbddcaa19ad..74322fe8c80e 100644
--- a/gnome-extra/gnome-software/metadata.xml
+++ b/gnome-extra/gnome-software/metadata.xml
@@ -1,8 +1,11 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <maintainer type="project">
-    <email>gnome@gentoo.org</email>
-    <name>Gentoo GNOME Desktop</name>
-  </maintainer>
+	<maintainer type="project">
+		<email>gnome@gentoo.org</email>
+		<name>Gentoo GNOME Desktop</name>
+	</maintainer>
+	<use>
+		<flag name="firmware">Enable firmware update support through <pkg>sys-apps/fwupd</pkg></flag>
+	</use>
 </pkgmetadata>