dev-python/pikepdf: Bump to 8.12.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index 1e5d8d0fb37e..277914a79cba 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -1,4 +1,5 @@
 DIST pikepdf-8.10.1.tar.gz 2866702 BLAKE2B a525b348bfd144623233f83cd194d0fbe3385d48242bd730fd00c2e660ffffe5d19eaf39d306824a6bc835f7ca9660459efa8a69135f86278ddc3271a05d1a24 SHA512 aad1135cbff9513a0a572aa35d8f408188573271c7f62473b4a0a8a86795587351240dddb53db59a4eb7a065b0a0921ffca1c6d1af5b8e48dc6beb9968f000d3
 DIST pikepdf-8.11.2.tar.gz 2870263 BLAKE2B 6cf3666baca5d20b125efc3f6d8cfe7f96b9334b8a39da67fe3f4185f41232d8a18bf902f21bfe33e4259b7fb61e7dc462a247c76bf4564a3bdf0ea987119d91 SHA512 57bf5d16aaf9367eef9407f7f406a5ee74f2060d276ab861379c74c2193d02b2e3cca0925ee29813791bb36fae8dbbba4a9b16a7f4c2d19c67c21bbe7bb3f80f
+DIST pikepdf-8.12.0.tar.gz 2870386 BLAKE2B f27c034ef94b63e56efa84abef987b23801ddb0c19c078715ffdf15596fb60b54a1159b3f43f6252418b51f967e9049912ba6950506811a41c766320148201e2 SHA512 9c6d269a7a8f806f22cc3df9f0147fc3c3a534b191e9db4f90c56a6ce9c695f7e9a20c44265551b0d2ca2a189d15c52dd602614baa44939d7ae943e698dec400
 DIST pikepdf-8.4.1.tar.gz 2853305 BLAKE2B 2298514159db17ba49b8e2fa2407d60de50273bea111ece704251d99193bdc4c8ed77f624237a49c3f4f129e3b14ac4ddd1006cf3024bcbf822bc5523e0fee35 SHA512 6989e8a3888f612e453ec1ea8425c0ca35ccfee19ae5e8c32df136ebc3fbb7728d9fe5beaacb4e392a20c9037a1009fc8f8d53d73634427fb0df9103626e34fa
 DIST pikepdf-8.8.0.tar.gz 2865070 BLAKE2B 78c26c577db858c27a1aa632c0e93a955eafc76f3e5928a5d4862408a71c02b66325e51728e81a5d6bd571655b2c96468592b3c591993e4cf6ecfa28fd997a89 SHA512 91bdf67a800c18559172c7a253859e6e5ef443b0f6e2d2f3af21042db2640f9d96a8fb5764e6ddd64ace248788e32b071ed624c95a6a0557ba19dc6fc33fdf76
diff --git a/dev-python/pikepdf/pikepdf-8.12.0.ebuild b/dev-python/pikepdf/pikepdf-8.12.0.ebuild
new file mode 100644
index 000000000000..f5173f73b2c1
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-8.12.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
+# https://qpdf.readthedocs.io/en/stable/release-notes.html.
+DEPEND="
+	>=app-text/qpdf-11.5.0:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecated[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-10.0.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+		>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/tomli[${PYTHON_USEDEP}]
+		' 3.10)
+		media-libs/tiff[zlib]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# fragile to system load
+	tests/test_image_access.py::test_random_image
+)
+
+src_prepare() {
+	sed -e '/-n auto/d' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p timeout
+}