app-misc/fastfetch: drop 2.9.0

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 0 insertions, 116 deletions

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 657745de13a9..fc1995e0dfda 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,4 +1,3 @@
 DIST fastfetch-2.7.1.tar.gz 1000565 BLAKE2B 061d2175bdca879bb4ef1a2f29fd73b99a7325fb8de66f05eb1203008c34ef20ff122e57a785ee0a5abb0251004023958abb1d158bc49cd1b34f9e02f3d1c6bc SHA512 55d897af532141d429aa5b58ab1516347f14597bf249b70f0d5ab27d11e235911858143fc32356255bef201cb44cdd7698e8d49094fb7e61c2e425a6c8ac5fa1
 DIST fastfetch-2.8.10.tar.gz 1290142 BLAKE2B 7a7ad65891850d96cc12d37b5e89359889afcdba6ccd30d834afd332ed072e00a719378ee3664a32b6e238fdca2fa1dc665768b078701b77837fefdacdce5027 SHA512 6b548c22239307f6dfcd90a4f995cbc77904adfd6f7ac809c7cd4c337a6783d768e2fd88d48e12c9b2c576893b74869d0a022f7129ccf37d853695ac3f5d488d
-DIST fastfetch-2.9.0.tar.gz 1290168 BLAKE2B 23ce26c574bd10a6d07db90cc0d8c5ecb11cd6977c8864dae28c94aecd852e1b3791a2930a07524d40ffb7bede1b9c1ff25dce3a999b0549285023b4382ca794 SHA512 d32341b8eed76b2e317947d6814ae255e2163e60bc1f3ac3fbb0ac74440216439cb7883dc42e59f0add8bd1b9401f067f7fbb89f1905ae8a902b3037c2ec2060
 DIST fastfetch-2.9.1.tar.gz 1291072 BLAKE2B 37269611614d36c2a3a0bbb650c9998c835223c6e593c7f8d139c5b90273c59dabf05632db8b6538836000eeac82d3b526b0499c3e0a5c99dc5555938a4f9340 SHA512 735a95af973cfb8680cdd7c0a6eaaeaabfa394ce3708d9836f49673d0331a9f4d4779a09516add1c7e5f817a05d175d7725144a3f8f040fac17ae3fbeeadad6a
diff --git a/app-misc/fastfetch/fastfetch-2.9.0.ebuild b/app-misc/fastfetch/fastfetch-2.9.0.ebuild
deleted file mode 100644
index 97a256518745..000000000000
--- a/app-misc/fastfetch/fastfetch-2.9.0.ebuild
+++ /dev/null
@@ -1,115 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic
-
-DESCRIPTION="Fast neofetch-like system information tool"
-HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
-if [[ ${PV} == *9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
-	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
-	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
-	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
-else
-	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
-fi
-
-LICENSE="MIT nvidia-gpu? ( NVIDIA-NVLM )"
-SLOT="0"
-IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager nvidia-gpu opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
-RESTRICT="!test? ( test )"
-
-# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
-# make sure to crank yyjson minimum version to match bundled version
-RDEPEND="
-	>=dev-libs/yyjson-0.8.0:=
-	sys-libs/zlib
-	X? ( x11-libs/libX11 )
-	chafa? ( media-gfx/chafa )
-	dbus? ( sys-apps/dbus )
-	ddcutil? ( app-misc/ddcutil:= )
-	drm? ( x11-libs/libdrm )
-	gnome? (
-		dev-libs/glib
-		gnome-base/dconf
-	)
-	imagemagick? ( media-gfx/imagemagick:= )
-	networkmanager? ( net-misc/networkmanager )
-	opencl? ( virtual/opencl )
-	opengl? ( media-libs/libglvnd[X] )
-	osmesa? ( media-libs/mesa[osmesa] )
-	pulseaudio? ( media-libs/libpulse )
-	sqlite? ( dev-db/sqlite:3 )
-	vulkan? (
-		media-libs/vulkan-loader
-		sys-apps/pciutils
-	)
-	wayland? ( dev-libs/wayland )
-	xcb? ( x11-libs/libxcb )
-	xfce? ( xfce-base/xfconf )
-	xrandr? ( x11-libs/libXrandr )
-"
-DEPEND="
-	${RDEPEND}
-	vulkan? ( dev-util/vulkan-headers )
-"
-BDEPEND="virtual/pkgconfig"
-
-REQUIRED_USE="
-	xrandr? ( X )
-	chafa? ( imagemagick )
-"
-
-src_configure() {
-	local fastfetch_enable_imagemagick7=no
-	local fastfetch_enable_imagemagick6=no
-	if use imagemagick; then
-		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
-	fi
-
-	local mycmakeargs=(
-		-DENABLE_RPM=no
-		-DENABLE_ZLIB=yes
-		-DENABLE_SYSTEM_YYJSON=yes
-
-		-DENABLE_CHAFA=$(usex chafa)
-		-DENABLE_DBUS=$(usex dbus)
-		-DENABLE_DCONF=$(usex gnome)
-		-DENABLE_DDCUTIL=$(usex ddcutil)
-		-DENABLE_DRM=$(usex drm)
-		-DENABLE_EGL=$(usex opengl)
-		-DENABLE_GIO=$(usex gnome)
-		-DENABLE_GLX=$(usex opengl)
-		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
-		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
-		-DENABLE_LIBNM=$(usex networkmanager)
-		-DENABLE_PROPRIETARY_GPU_DRIVER_API=$(usex nvidia-gpu)
-		-DENABLE_OPENCL=$(usex opencl)
-		-DENABLE_OSMESA=$(usex osmesa)
-		-DENABLE_PULSE=$(usex pulseaudio)
-		-DENABLE_SQLITE3=$(usex sqlite)
-		-DENABLE_VULKAN=$(usex vulkan)
-		-DENABLE_WAYLAND=$(usex wayland)
-		-DENABLE_X11=$(usex X)
-		-DENABLE_XCB=$(usex xcb)
-		-DENABLE_XCB_RANDR=$(usex xcb)
-		-DENABLE_XFCONF=$(usex xfce)
-		-DENABLE_XRANDR=$(usex xrandr)
-		-DBUILD_TESTS=$(usex test)
-	)
-
-	append-cppflags -DNDEBUG
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	rm -r "${ED}"/usr/share/licenses || die
-}