blob: 034d986b5a2d017bc9995fb3a037281868248601 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 2022-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1 systemd
DESCRIPTION="A bouncer-style Matrix IRC bridge"
HOMEPAGE="https://github.com/hifi/heisenbridge/"
SRC_URI="https://github.com/hifi/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
acct-user/heisenbridge
<dev-python/aiohttp-4[${PYTHON_USEDEP}]
dev-python/async-timeout[${PYTHON_USEDEP}]
dev-python/irc[${PYTHON_USEDEP}]
dev-python/mautrix[${PYTHON_USEDEP}]
dev-python/python-socks[${PYTHON_USEDEP}]
dev-python/ruamel-yaml[${PYTHON_USEDEP}]
"
PATCHES=(
"${FILESDIR}/heisenbridge-1.14.1-qanotice.patch"
)
distutils_enable_tests pytest
src_prepare() {
distutils-r1_src_prepare
echo ${PV} > ${PN}/version.txt || die
}
src_install() {
distutils-r1_src_install
newinitd "${FILESDIR}"/heisenbridge.initd ${PN}
newconfd "${FILESDIR}"/heisenbridge.confd ${PN}
systemd_dounit "${FILESDIR}"/${PN}.service
}
pkg_postinst() {
[[ -f "${EPREFIX}"/var/lib/${PN}/registration.yaml ]] && return 0
einfo
elog "Before you can use ${PN}, you have to configure it correctly."
elog "The configuration file is located at /etc/conf.d/${PN}"
elog
elog "Then, you must generate the registration file using the following command:"
elog "* If you are using Synapse:"
elog "\t${PN} -c /var/lib/${PN}/registration.yaml --generate https://example.com"
elog "* If you are using Dendrite, Conduit or others:"
elog "\t${PN} -c /var/lib/${PN}/registration.yaml --generate-compat https://example.com"
elog
elog "Notice the URL at the end, replace it with your homeserver's URL."
elog "Then, you must register the bridge with your homeserver."
elog "Refer to your homeserver's documentation for instructions."
elog "The registration file is located at /var/lib/${PN}/registration.yaml"
elog "Finally, you may start the ${PN} daemon."
einfo
}
|
GitWeb
