kde-base/printer-applet/printer-applet-4.7.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/printer-applet/printer-applet-4.7.4.ebuild,v 1.2 2012/01/09 17:47:45 phajdan.jr Exp $

EAPI=4

KDE_HANDBOOK="optional"
PYTHON_DEPEND="2"
KDE_SCM="git"
if [[ ${PV} == *9999 ]]; then
	kde_eclass="kde4-base"
else
	KMNAME="kdeutils"
	kde_eclass="kde4-meta"
fi
inherit python ${kde_eclass}

DESCRIPTION="KDE printer system tray utility"
KEYWORDS="~amd64 ~ppc ~ppc64 x86"
IUSE=""

DEPEND="
	>=app-admin/system-config-printer-common-1.2.2
	$(add_kdebase_dep pykde4)
"
RDEPEND="${DEPEND}"

pkg_setup() {
	${kde_eclass}_pkg_setup
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	${kde_eclass}_src_prepare

	# Rename printer-applet -> printer-applet-kde
	local newname="printer-applet-kde"
	local srcdir=.
	[[ ${kde_eclass} == "kde4-meta" ]] && srcdir="${KMMODULE}"
	sed -e "/PYKDE4_ADD_EXECUTABLE/s/ printer-applet[[:space:]]*)/ ${newname})/" \
		-e "/install/s/)/ RENAME ${newname}.desktop)/" \
		-i "${srcdir}"/CMakeLists.txt || die "failed to rename printer-applet executable"
	sed -e "/Exec/s/printer-applet/${newname}/" \
		-i "${srcdir}"/printer-applet.desktop || die "failed to patch .desktop file"
}

src_install() {
	${kde_eclass}_src_install
	python_convert_shebangs -q -r $(python_get_version) "${ED}"
}

pkg_postrm() {
	python_mod_cleanup "${PREFIX}share/apps/${PN}"
}