Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status
summaryrefslogtreecommitdiff
path: root/net-fs
diff options
context:
space:
mode:
Diffstat (limited to 'net-fs')
-rw-r--r--net-fs/openafs-kernel/ChangeLog9
-rw-r--r--net-fs/openafs-kernel/openafs-kernel-1.4.14.1.ebuild68
-rw-r--r--net-fs/openafs-kernel/openafs-kernel-1.6.0.ebuild66
-rw-r--r--net-fs/openafs/ChangeLog9
-rw-r--r--net-fs/openafs/openafs-1.4.14.1.ebuild147
-rw-r--r--net-fs/openafs/openafs-1.6.0.ebuild151
6 files changed, 448 insertions, 2 deletions
diff --git a/net-fs/openafs-kernel/ChangeLog b/net-fs/openafs-kernel/ChangeLog
index 5d5642fed8d3..3320d1e24362 100644
--- a/net-fs/openafs-kernel/ChangeLog
+++ b/net-fs/openafs-kernel/ChangeLog
@@ -1,6 +1,13 @@
# ChangeLog for net-fs/openafs-kernel
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/ChangeLog,v 1.133 2011/09/18 21:31:57 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/ChangeLog,v 1.134 2011/09/18 21:34:21 vapier Exp $
+
+*openafs-kernel-1.6.0 (18 Sep 2011)
+*openafs-kernel-1.4.14.1 (18 Sep 2011)
+
+ 18 Sep 2011; Mike Frysinger <vapier@gentoo.org>
+ +openafs-kernel-1.4.14.1.ebuild, +openafs-kernel-1.6.0.ebuild:
+ Version bump #383473 by Andrej Filipcic.
18 Sep 2011; Mike Frysinger <vapier@gentoo.org> -openafs-kernel-1.4.9.ebuild,
-openafs-kernel-1.4.12.1.ebuild, -openafs-kernel-1.5.34.ebuild,
diff --git a/net-fs/openafs-kernel/openafs-kernel-1.4.14.1.ebuild b/net-fs/openafs-kernel/openafs-kernel-1.4.14.1.ebuild
new file mode 100644
index 000000000000..3c2295531947
--- /dev/null
+++ b/net-fs/openafs-kernel/openafs-kernel-1.4.14.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/openafs-kernel-1.4.14.1.ebuild,v 1.1 2011/09/18 21:34:21 vapier Exp $
+
+EAPI="2"
+
+inherit eutils autotools linux-mod versionator toolchain-funcs linux-info
+
+KV_max=2.6.38
+MY_PN=${PN/-kernel}
+MY_P=${MY_PN}-${PV}
+MY_PV=$(get_version_component_range 1-4)
+PVER="1"
+DESCRIPTION="The OpenAFS distributed file system kernel module"
+HOMEPAGE="http://www.openafs.org/"
+SRC_URI="http://openafs.org/dl/${MY_PV}/${MY_P}-src.tar.bz2
+ mirror://gentoo/${MY_P}-patches-${PVER}.tar.bz2"
+
+LICENSE="IBM BSD openafs-krb5-a APSL-2 sun-rpc"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE=""
+
+S=${WORKDIR}/${MY_P}
+
+CONFIG_CHECK="!DEBUG_RODATA ~!AFS_FS KEYS"
+ERROR_DEBUG_RODATA="OpenAFS is incompatible with linux' CONFIG_DEBUG_RODATA option"
+ERROR_AFS_FS="OpenAFS conflicts with the in-kernel AFS-support. Make sure not to load both at the same time!"
+
+pkg_setup() {
+ if kernel_is -gt ${KV_max//./ }
+ then
+ eerror "${P} does not support Linux kernel version ${KV_max} or higher"
+ die
+ fi
+ linux-mod_pkg_setup
+}
+
+src_prepare() {
+ EPATCH_EXCLUDE="012_all_kbuild.patch" \
+ EPATCH_SUFFIX="patch" \
+ epatch "${WORKDIR}"/gentoo/patches
+
+ # packaging is f-ed up, so we can't run automake (i.e. eautoreconf)
+ sed -i '/^a/s:^:e:' regen.sh
+ skipman=1
+ . regen.sh
+}
+
+src_configure() {
+ ARCH="$(tc-arch-kernel)" \
+ econf \
+ --with-linux-kernel-headers=${KV_DIR} \
+ --with-linux-kernel-build=${KV_OUT_DIR}
+}
+
+src_compile() {
+ ARCH="$(tc-arch-kernel)" emake -j1 only_libafs || die
+}
+
+src_install() {
+ MOD_SRCDIR=$(expr "${S}"/src/libafs/MODLOAD-*)
+ [ -f "${MOD_SRCDIR}"/libafs.${KV_OBJ} ] || die "Couldn't find compiled kernel module"
+
+ MODULE_NAMES='libafs(fs/openafs:$MOD_SRCDIR)'
+
+ linux-mod_src_install
+}
diff --git a/net-fs/openafs-kernel/openafs-kernel-1.6.0.ebuild b/net-fs/openafs-kernel/openafs-kernel-1.6.0.ebuild
new file mode 100644
index 000000000000..9af37d29076f
--- /dev/null
+++ b/net-fs/openafs-kernel/openafs-kernel-1.6.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs-kernel/openafs-kernel-1.6.0.ebuild,v 1.1 2011/09/18 21:34:21 vapier Exp $
+
+EAPI="2"
+
+inherit eutils autotools linux-mod versionator toolchain-funcs
+
+MY_PV=$(delete_version_separator '_')
+MY_PN=${PN/-kernel}
+MY_P2="${MY_PN}-${PV}"
+MY_P="${MY_PN}-${MY_PV}"
+PVER="1"
+DESCRIPTION="The OpenAFS distributed file system kernel module"
+HOMEPAGE="http://www.openafs.org/"
+# We always d/l the doc tarball as man pages are not USE=doc material
+SRC_URI="http://openafs.org/dl/openafs/${MY_PV}/${MY_P}-src.tar.bz2
+ mirror://gentoo/${MY_P2}-patches-${PVER}.tar.bz2"
+
+LICENSE="IBM BSD openafs-krb5-a APSL-2 sun-rpc"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE=""
+
+S=${WORKDIR}/${MY_P}
+
+CONFIG_CHECK="!DEBUG_RODATA ~!AFS_FS KEYS"
+ERROR_DEBUG_RODATA="OpenAFS is incompatible with linux' CONFIG_DEBUG_RODATA option"
+ERROR_AFS_FS="OpenAFS conflicts with the in-kernel AFS-support. Make sure not to load both at the same time!"
+ERROR_KEYS="OpenAFS needs CONFIG_KEYS option enabled"
+
+pkg_setup() {
+ linux-mod_pkg_setup
+}
+
+src_prepare() {
+ EPATCH_EXCLUDE="012_all_kbuild.patch" \
+ EPATCH_SUFFIX="patch" \
+ epatch "${WORKDIR}"/gentoo/patches
+
+ # packaging is f-ed up, so we can't run automake (i.e. eautoreconf)
+ sed -i 's/^\(\s*\)a/\1ea/' regen.sh
+ : # this line makes repoman ok with not calling eautoconf etc. directly
+ skipman=1
+ . regen.sh
+}
+
+src_configure() {
+ ARCH="$(tc-arch-kernel)" \
+ econf \
+ --with-linux-kernel-headers=${KV_DIR} \
+ --with-linux-kernel-build=${KV_OUT_DIR}
+}
+
+src_compile() {
+ ARCH="$(tc-arch-kernel)" emake -j1 only_libafs || die
+}
+
+src_install() {
+ MOD_SRCDIR=$(expr "${S}"/src/libafs/MODLOAD-*)
+ [ -f "${MOD_SRCDIR}"/libafs.${KV_OBJ} ] || die "Couldn't find compiled kernel module"
+
+ MODULE_NAMES='libafs(fs/openafs:$MOD_SRCDIR)'
+
+ linux-mod_src_install
+}
diff --git a/net-fs/openafs/ChangeLog b/net-fs/openafs/ChangeLog
index 43014c7c79da..8cb9a4ca66b6 100644
--- a/net-fs/openafs/ChangeLog
+++ b/net-fs/openafs/ChangeLog
@@ -1,6 +1,13 @@
# ChangeLog for net-fs/openafs
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs/ChangeLog,v 1.176 2011/09/18 21:31:29 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs/ChangeLog,v 1.177 2011/09/18 21:35:28 vapier Exp $
+
+*openafs-1.6.0 (18 Sep 2011)
+*openafs-1.4.14.1 (18 Sep 2011)
+
+ 18 Sep 2011; Mike Frysinger <vapier@gentoo.org> +openafs-1.4.14.1.ebuild,
+ +openafs-1.6.0.ebuild:
+ Version bump #383473 by Andrej Filipcic.
18 Sep 2011; Mike Frysinger <vapier@gentoo.org> -openafs-1.4.9.ebuild,
-openafs-1.4.12.1-r2.ebuild, -openafs-1.4.14.ebuild, -openafs-1.5.34.ebuild,
diff --git a/net-fs/openafs/openafs-1.4.14.1.ebuild b/net-fs/openafs/openafs-1.4.14.1.ebuild
new file mode 100644
index 000000000000..3a135be1c020
--- /dev/null
+++ b/net-fs/openafs/openafs-1.4.14.1.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs/openafs-1.4.14.1.ebuild,v 1.1 2011/09/18 21:35:28 vapier Exp $
+
+EAPI="2"
+
+inherit flag-o-matic eutils autotools toolchain-funcs versionator pam
+
+MY_PV=$(get_version_component_range 1-4)
+PVER="1"
+DESCRIPTION="The OpenAFS distributed file system"
+HOMEPAGE="http://www.openafs.org/"
+# We always d/l the doc tarball as man pages are not USE=doc material
+SRC_URI="http://openafs.org/dl/${MY_PV}/${P}-src.tar.bz2
+ http://openafs.org/dl/${MY_PV}/${P}-doc.tar.bz2
+ mirror://gentoo/${P}-patches-${PVER}.tar.bz2"
+
+LICENSE="IBM BSD openafs-krb5-a APSL-2 sun-rpc"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE="doc kerberos pam"
+
+RDEPEND="~net-fs/openafs-kernel-${PV}
+ pam? ( sys-libs/pam )
+ kerberos? ( virtual/krb5 )"
+
+src_prepare() {
+ EPATCH_EXCLUDE="012_all_kbuild.patch" \
+ EPATCH_SUFFIX="patch" \
+ epatch "${WORKDIR}"/gentoo/patches
+
+ # packaging is f-ed up, so we can't run automake (i.e. eautoreconf)
+ sed -i '/^a/s:^:e:' regen.sh
+ skipman=1
+ . regen.sh
+}
+
+src_configure() {
+ # cannot use "use_with" macro, as --without-krb5-config crashes the econf
+ local myconf=""
+ if use kerberos; then
+ myconf="--with-krb5-conf=$(type -p krb5-config)"
+ fi
+
+ AFS_SYSKVERS=26 \
+ XCFLAGS="${CFLAGS}" \
+ econf \
+ $(use_enable pam) \
+ --enable-largefile-fileserver \
+ --enable-supergroups \
+ --disable-kernel-module \
+ --disable-strip-binaries \
+ ${myconf}
+}
+
+src_compile() {
+ emake -j1 all_nolibafs || die
+}
+
+src_install() {
+ local CONFDIR=${WORKDIR}/gentoo/configs
+ local SCRIPTDIR=${WORKDIR}/gentoo/scripts
+
+ emake -j1 DESTDIR="${D}" install_nolibafs || die
+
+ insinto /etc/openafs
+ doins src/afsd/CellServDB || die
+ echo "/afs:/var/cache/openafs:200000" > "${D}"/etc/openafs/cacheinfo
+ echo "openafs.org" > "${D}"/etc/openafs/ThisCell
+
+ # pam_afs and pam_afs.krb have been installed in irregular locations, fix
+ if use pam ; then
+ dopammod "${D}"/usr/$(get_libdir)/pam_afs* || die
+ fi
+ rm -f "${D}"/usr/$(get_libdir)/pam_afs* || die
+
+ # remove kdump stuff provided by kexec-tools #222455
+ rm -rf "${D}"/usr/sbin/kdump*
+
+ # avoid collision with mit_krb5's version of kpasswd
+ mv "${D}"/usr/bin/kpasswd{,_afs} || die
+ mv "${D}"/usr/share/man/man1/kpasswd{,_afs}.1 || die
+
+ # move lwp stuff around #200674 #330061
+ mv "${D}"/usr/include/{lwp,lock,timer}.h "${D}"/usr/include/afs/ || die
+ mv "${D}"/usr/$(get_libdir)/liblwp* "${D}"/usr/$(get_libdir)/afs/ || die
+ # update paths to the relocated lwp headers
+ sed -ri \
+ -e '/^#include <(lwp|lock|timer).h>/s:<([^>]*)>:<afs/\1>:' \
+ "${D}"/usr/include/*.h \
+ "${D}"/usr/include/*/*.h \
+ || die
+
+ # minimal documentation
+ use pam && doman src/pam/pam_afs.5
+ dodoc "${CONFDIR}"/README src/afsd/CellServDB
+
+ # documentation package
+ if use doc ; then
+ dodoc doc/{arch,examples,pdf,protocol,txt}/*
+ dohtml -A xml -r doc/{html,xml}/*
+ fi
+
+ # Gentoo related scripts
+ newinitd "${SCRIPTDIR}"/openafs-client openafs-client || die
+ newconfd "${CONFDIR}"/openafs-client openafs-client || die
+ newinitd "${SCRIPTDIR}"/openafs-server openafs-server || die
+ newconfd "${CONFDIR}"/openafs-server openafs-server || die
+
+ # used directories: client
+ keepdir /etc/openafs
+ keepdir /var/cache/openafs
+
+ # used directories: server
+ keepdir /etc/openafs/server
+ diropts -m0700
+ keepdir /var/lib/openafs
+ keepdir /var/lib/openafs/db
+ diropts -m0755
+ keepdir /var/lib/openafs/logs
+
+ # link logfiles to /var/log
+ dosym ../lib/openafs/logs /var/log/openafs
+}
+
+pkg_preinst() {
+ ## Somewhat intelligently install default configuration files
+ ## (when they are not present)
+ local x
+ for x in cacheinfo CellServDB ThisCell ; do
+ if [ -e "${ROOT}"/etc/openafs/${x} ] ; then
+ cp "${ROOT}"/etc/openafs/${x} "${D}"/etc/openafs/
+ fi
+ done
+}
+
+pkg_postinst() {
+ elog "This installation should work out of the box (at least the"
+ elog "client part doing global afs-cell browsing, unless you had"
+ elog "a previous and different configuration). If you want to"
+ elog "set up your own cell or modify the standard config,"
+ elog "please have a look at the Gentoo OpenAFS documentation"
+ elog "(warning: it is not yet up to date wrt the new file locations)"
+ elog
+ elog "The documentation can be found at:"
+ elog " http://www.gentoo.org/doc/en/openafs.xml"
+}
diff --git a/net-fs/openafs/openafs-1.6.0.ebuild b/net-fs/openafs/openafs-1.6.0.ebuild
new file mode 100644
index 000000000000..7730268370a2
--- /dev/null
+++ b/net-fs/openafs/openafs-1.6.0.ebuild
@@ -0,0 +1,151 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-fs/openafs/openafs-1.6.0.ebuild,v 1.1 2011/09/18 21:35:28 vapier Exp $
+
+EAPI="2"
+
+inherit flag-o-matic eutils autotools toolchain-funcs versionator pam
+
+MY_PV=$(delete_version_separator '_')
+MY_P="${PN}-${MY_PV}"
+PVER="1"
+DESCRIPTION="The OpenAFS distributed file system"
+HOMEPAGE="http://www.openafs.org/"
+# We always d/l the doc tarball as man pages are not USE=doc material
+SRC_URI="http://openafs.org/dl/openafs/${MY_PV}/${MY_P}-src.tar.bz2
+ http://openafs.org/dl/openafs/${MY_PV}/${MY_P}-doc.tar.bz2
+ mirror://gentoo/${P}-patches-${PVER}.tar.bz2"
+
+LICENSE="IBM BSD openafs-krb5-a APSL-2 sun-rpc"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE="doc kerberos pam"
+
+RDEPEND="~net-fs/openafs-kernel-${PV}
+ sys-libs/ncurses
+ pam? ( sys-libs/pam )
+ kerberos? ( virtual/krb5 )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+ EPATCH_EXCLUDE="012_all_kbuild.patch" \
+ EPATCH_SUFFIX="patch" \
+ epatch "${WORKDIR}"/gentoo/patches
+
+ # packaging is f-ed up, so we can't run automake (i.e. eautoreconf)
+ sed -i 's/^\(\s*\)a/\1ea/' regen.sh
+ : # this line makes repoman ok with not calling eautoconf etc. directly
+ skipman=1
+ . regen.sh
+}
+
+src_configure() {
+ # cannot use "use_with" macro, as --without-krb5-config crashes the econf
+ local myconf=""
+ if use kerberos; then
+ myconf="--with-krb5-conf=$(type -p krb5-config)"
+ fi
+
+ AFS_SYSKVERS=26 \
+ XCFLAGS="${CFLAGS}" \
+ econf \
+ $(use_enable pam) \
+ --enable-supergroups \
+ --disable-kernel-module \
+ --disable-strip-binaries \
+ ${myconf}
+}
+
+src_compile() {
+ emake all_nolibafs || die
+}
+
+src_install() {
+ local CONFDIR=${WORKDIR}/gentoo/configs
+ local SCRIPTDIR=${WORKDIR}/gentoo/scripts
+
+ emake DESTDIR="${D}" install_nolibafs || die
+
+ insinto /etc/openafs
+ doins src/afsd/CellServDB || die
+ echo "/afs:/var/cache/openafs:200000" > "${D}"/etc/openafs/cacheinfo
+ echo "openafs.org" > "${D}"/etc/openafs/ThisCell
+
+ # pam_afs and pam_afs.krb have been installed in irregular locations, fix
+ if use pam ; then
+ dopammod "${D}"/usr/$(get_libdir)/pam_afs* || die
+ fi
+ rm -f "${D}"/usr/$(get_libdir)/pam_afs* || die
+
+ # remove kdump stuff provided by kexec-tools #222455
+ rm -rf "${D}"/usr/sbin/kdump*
+
+ # avoid collision with mit_krb5's version of kpasswd
+ mv "${D}"/usr/bin/kpasswd{,_afs} || die
+ mv "${D}"/usr/share/man/man1/kpasswd{,_afs}.1 || die
+
+ # move lwp stuff around #200674 #330061
+ mv "${D}"/usr/include/{lwp,lock,timer}.h "${D}"/usr/include/afs/ || die
+ mv "${D}"/usr/$(get_libdir)/liblwp* "${D}"/usr/$(get_libdir)/afs/ || die
+ # update paths to the relocated lwp headers
+ sed -ri \
+ -e '/^#include <(lwp|lock|timer).h>/s:<([^>]*)>:<afs/\1>:' \
+ "${D}"/usr/include/*.h \
+ "${D}"/usr/include/*/*.h \
+ || die
+
+ # minimal documentation
+ use pam && doman src/pam/pam_afs.5
+ dodoc "${CONFDIR}"/README src/afsd/CellServDB
+
+ # documentation package
+ if use doc ; then
+ dodoc doc/{arch,examples,pdf,protocol,txt}/*
+ dohtml -A xml -r doc/{html,xml}/*
+ fi
+
+ # Gentoo related scripts
+ newinitd "${SCRIPTDIR}"/openafs-client openafs-client || die
+ newconfd "${CONFDIR}"/openafs-client openafs-client || die
+ newinitd "${SCRIPTDIR}"/openafs-server openafs-server || die
+ newconfd "${CONFDIR}"/openafs-server openafs-server || die
+
+ # used directories: client
+ keepdir /etc/openafs
+ keepdir /var/cache/openafs
+
+ # used directories: server
+ keepdir /etc/openafs/server
+ diropts -m0700
+ keepdir /var/lib/openafs
+ keepdir /var/lib/openafs/db
+ diropts -m0755
+ keepdir /var/lib/openafs/logs
+
+ # link logfiles to /var/log
+ dosym ../lib/openafs/logs /var/log/openafs
+}
+
+pkg_preinst() {
+ ## Somewhat intelligently install default configuration files
+ ## (when they are not present)
+ local x
+ for x in cacheinfo CellServDB ThisCell ; do
+ if [ -e "${ROOT}"/etc/openafs/${x} ] ; then
+ cp "${ROOT}"/etc/openafs/${x} "${D}"/etc/openafs/
+ fi
+ done
+}
+
+pkg_postinst() {
+ elog "This installation should work out of the box (at least the"
+ elog "client part doing global afs-cell browsing, unless you had"
+ elog "a previous and different configuration). If you want to"
+ elog "set up your own cell or modify the standard config,"
+ elog "please have a look at the Gentoo OpenAFS documentation"
+ elog "(warning: it is not yet up to date wrt the new file locations)"
+ elog
+ elog "The documentation can be found at:"
+ elog " http://www.gentoo.org/doc/en/openafs.xml"
+}