1 files changed, 45 insertions, 0 deletions
diff --git a/dev-ruby/storable/storable-0.7.1-r1.ebuild b/dev-ruby/storable/storable-0.7.1-r1.ebuild
new file mode 100644
index 000000000000..c0dffe37a701
--- /dev/null
+++ b/dev-ruby/storable/storable-0.7.1-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/storable/storable-0.7.1-r1.ebuild,v 1.1 2010/04/06 08:48:36 flameeyes Exp $
+
+EAPI=2
+
+USE_RUBY="ruby18 ruby19 jruby"
+
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_TASK_DOC="rdoc"
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGES.txt README.rdoc"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Marshal Ruby classes into and out of multiple formats"
+HOMEPAGE="http://solutious.com/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+SRC_URI="http://github.com/delano/${PN}/tarball/v${PV} -> ${PN}-git-${PV}.tgz"
+S="${WORKDIR}/delano-${PN}-a465c45"
+
+ruby_add_bdepend test dev-ruby/tryouts
+
+all_ruby_prepare() {
+	mv bin examples || die
+
+	epatch "${FILESDIR}"/${P}-emptysymbol.patch
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib -S sergeant || die "tests failed"
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc examples/* || die
+}