1 files changed, 50 insertions, 0 deletions
diff --git a/app-text/qpdf/qpdf-3.0.0.ebuild b/app-text/qpdf/qpdf-3.0.0.ebuild
new file mode 100644
index 000000000000..b1494e8e096a
--- /dev/null
+++ b/app-text/qpdf/qpdf-3.0.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/qpdf/qpdf-3.0.0.ebuild,v 1.1 2012/08/06 23:55:05 radhermit Exp $
+
+EAPI="4"
+
+DESCRIPTION="A command-line program that does structural, content-preserving transformations on PDF files"
+HOMEPAGE="http://qpdf.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qpdf/${P}.tar.gz"
+
+LICENSE="Artistic-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples static-libs test"
+
+RDEPEND="dev-libs/libpcre
+	sys-libs/zlib
+	>=dev-lang/perl-5.8"
+DEPEND="${RDEPEND}
+	test? (
+		sys-apps/diffutils
+		media-libs/tiff
+		app-text/ghostscript-gpl
+	)"
+
+DOCS=( ChangeLog README TODO )
+
+src_prepare() {
+	# Manually install docs
+	sed -i -e "/docdir/d" make/libtool.mk || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable test test-compare-images)
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		dodoc doc/qpdf-manual.pdf
+		dohtml doc/*
+	fi
+
+	if use examples ; then
+		dobin examples/build/.libs/*
+	fi
+}