blob: f83373ad3e87c9ae9ba05bd47833710df665ec54 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
# NOTE: Please bump with net-misc/gsasl
DESCRIPTION="The GNU SASL library"
HOMEPAGE="https://www.gnu.org/software/gsasl/"
SRC_URI="mirror://gnu/${PN/lib}/${P}.tar.gz"
LICENSE="GPL-3 LGPL-3"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos"
IUSE="idn gcrypt kerberos nls ntlm static-libs"
DEPEND="
gcrypt? ( dev-libs/libgcrypt:0= )
idn? ( net-dns/libidn:= )
kerberos? ( virtual/krb5 )
nls? ( >=sys-devel/gettext-0.18.1 )
ntlm? ( net-libs/libntlm )
"
RDEPEND="${DEPEND}
!net-misc/gsasl"
PATCHES=(
"${FILESDIR}"/${PN}-1.8.1-gss-extra.patch
"${FILESDIR}"/${PN}-1.8.1-ac-270.patch
)
src_prepare() {
default
sed -i -e 's/ -Werror//' configure.ac || die
eautoreconf
}
src_configure() {
local krb5_impl
if use kerberos; then
krb5_impl="--with-gssapi-impl="
# These are the two providers of virtual/krb5
if has_version app-crypt/mit-krb5; then
krb5_impl+="mit"
else
krb5_impl+="heimdal"
fi
fi
local myeconfargs=(
$(use_with gcrypt libgcrypt)
$(use_with idn stringprep)
$(use_enable kerberos gssapi)
${krb5_impl}
$(use_enable nls)
$(use_enable ntlm)
$(use_enable static-libs static)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
if ! use static-libs; then
rm -f "${ED}"/usr/lib*/lib*.la || die
fi
}
|
GitWeb
