blob: c67040512394e2b179ecbc0fbfb732959bb5e9e2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit meson python-r1 vala
DESCRIPTION="Accounts SSO (Single Sign-On) management library for GLib applications"
HOMEPAGE="https://gitlab.com/accounts-sso/libaccounts-glib"
SRC_URI="https://gitlab.com/accounts-sso/${PN}/-/archive/VERSION_${PV}/${PN}-VERSION_${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-VERSION_${PV}"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv x86"
IUSE="doc"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
# fails
RESTRICT="test"
RDEPEND="${PYTHON_DEPS}
dev-db/sqlite:3
dev-libs/glib:2
dev-libs/gobject-introspection:=
dev-libs/libxml2
dev-python/pygobject:3[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}"
BDEPEND="
$(vala_depend)
dev-libs/check
dev-util/gdbus-codegen
dev-util/glib-utils
doc? ( dev-util/gtk-doc )
"
PATCHES=(
"${FILESDIR}/${PN}-1.25-assert-failure.patch"
"${FILESDIR}/${P}-project-version.patch"
"${FILESDIR}/${P}-fix-incorrect-cleanup-in-ag_account_finalize.patch"
)
src_prepare() {
default
vala_setup --ignore-use
use doc || sed -e "/^subdir('docs')$/d" -i meson.build || die
}
src_configure() {
python_foreach_impl run_in_build_dir meson_src_configure
}
src_compile() {
python_foreach_impl run_in_build_dir meson_src_compile
}
src_install() {
einstalldocs
python_foreach_impl run_in_build_dir meson_src_install
python_foreach_impl python_optimize
}
|
GitWeb
