blob: a2201f89d33fa41fd48865d40dc137f163748dae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DESCRIPTION="Generic build tool with built-in rules for building OCaml library and programs"
HOMEPAGE="https://github.com/ocaml/ocamlbuild"
SRC_URI="https://github.com/ocaml/ocamlbuild/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="LGPL-2.1-with-linking-exception"
SLOT="0/${PV}"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ~ppc ppc64 x86 ~amd64-linux ~x86-linux"
IUSE="+ocamlopt test"
RESTRICT="!test? ( test )"
REQUIRED_USE="test? ( ocamlopt )"
RDEPEND=">=dev-lang/ocaml-4.02.3-r1:=[ocamlopt?]"
DEPEND="${RDEPEND}
dev-ml/findlib"
PATCHES=(
"${FILESDIR}"/${PN}-0.14.0-Disable-tests-failing-with-OCaml-4.08.0.patch
)
QA_FLAGS_IGNORED='.*'
src_prepare() {
sed -i \
-e "/package_exists/s:camlp4.macro:xxxxxx:" \
-e "/package_exists/s:menhirLib:xxxxxx:" \
testsuite/external.ml || die
default
}
src_configure() {
emake -f configure.make Makefile.config \
PREFIX="${EPREFIX}/usr" \
BINDIR="${EPREFIX}/usr/bin" \
LIBDIR="$(ocamlc -where)" \
OCAML_NATIVE=$(usex ocamlopt true false) \
OCAML_NATIVE_TOOLS=$(usex ocamlopt true false) \
NATDYNLINK=$(usex ocamlopt true false)
}
src_compile() {
emake src/ocamlbuild_config.cmo
default
}
src_install() {
emake CHECK_IF_PREINSTALLED=false DESTDIR="${D}" install
dodoc Changes
}
|
GitWeb
