From ebacfac367fa872515eae4c4296104e83d00fbcd Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Sun, 20 May 2018 19:15:04 -0700
Subject: dev-libs/libinput: Version bump 1.10.7

Straight to stable.
---
 dev-libs/libinput/Manifest               |  1 +
 dev-libs/libinput/libinput-1.10.7.ebuild | 56 ++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 dev-libs/libinput/libinput-1.10.7.ebuild

(limited to 'dev-libs')

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index f2daf54f05b0..1746dd868037 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1 +1,2 @@
 DIST libinput-1.10.6.tar.xz 495536 BLAKE2B 3f23808635406eeb66cd6b4ce2a2dbaed69ee0917045f75ad262a59702d72923493b6faa7951ea3f7cc2591d4c9e1fc49cffc53b6dfbcb2aadc7b9f40c20517b SHA512 b76963c3429c5590ee04f1da94d08775c8bb8584830e678804fb1d4cf0e2af84826782eae71fdd57492461f85df87ac2fc940c280b0672c75cd81d5f34702fe4
+DIST libinput-1.10.7.tar.xz 494648 BLAKE2B ddcbe5f54b90f8291c16e5912fa3d673fb2c66f0247c9d771f7c2dfeeef9b51404f31d7ac99cfd20b37e1d01d6b2b3bc95155ab6581c6a94e922e153d9098892 SHA512 b102b8065ceed7511ad26efba34d5d9b0c13f0f7aaa882bb21501f7a5166f4cbe140fcbb488e90e6880bd47bb2b27667a4d6aa79b8726269fa1337897034a684
diff --git a/dev-libs/libinput/libinput-1.10.7.ebuild b/dev-libs/libinput/libinput-1.10.7.ebuild
new file mode 100644
index 000000000000..9e10a1005467
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.10.7.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit meson udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86"
+IUSE="doc input_devices_wacom test"
+# Tests require write access to udev rules directory which is a no-no for live system.
+# Other tests are just about logs, exported symbols and autotest of the test library.
+RESTRICT="test"
+
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+	>=dev-libs/libevdev-1.3
+	>=sys-libs/mtdev-1.1
+	virtual/libudev
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? (
+#		>=dev-libs/check-0.9.10
+#		dev-util/valgrind
+#		sys-libs/libunwind )
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		-Ddocumentation="$(usex doc true false)"
+		-Dlibwacom="$(usex input_devices_wacom true false)"
+		-Dtests="$(usex test true false)"
+		-Dudev-dir="$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/html/.
+	fi
+	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
+}
-- 
cgit v1.2.3-65-gdbad