2 files changed, 72 insertions, 0 deletions
diff --git a/net-libs/libnma/Manifest b/net-libs/libnma/Manifest
index 7f253b82e0ed..e80be6ac4526 100644
--- a/net-libs/libnma/Manifest
+++ b/net-libs/libnma/Manifest
@@ -1 +1,2 @@
 DIST libnma-1.8.38.tar.xz 1347004 BLAKE2B 108fc7d0a01ca72c84a738f831d442d82990f7b82301de3a47d8331af1e080a33c10806fb75830463fbfb8a4a1f556cdf5272ee52dbc4616ea3dbca1959cd128 SHA512 0421c598ccb6e3659f182b596eec76ffd695e51c11fd11b8325c2d08cb259536d7e74c11bbaac3ccb841016a0bc69a87f1c682b934a9eb569a74116e677eba63
+DIST libnma-1.8.40.tar.xz 1350560 BLAKE2B 9c5124a1dcaa801c7d0135ef64dedccd098988fdd199938e2409e80bee86df71bf368cada113dceae4046a5c2c5fe954aa9fc0c19519721a4e8ec7b8f7ea8d44 SHA512 28f4704f97941308f43b27a309fd14050e8ac7e0c6665cada3cc08a759e140f043a80b21ccfe02ce348f8490cad8107b4fe27026dbaafed46ec1c7c46824e3b8
diff --git a/net-libs/libnma/libnma-1.8.40.ebuild b/net-libs/libnma/libnma-1.8.40.ebuild
new file mode 100644
index 000000000000..76713c40ed01
--- /dev/null
+++ b/net-libs/libnma/libnma-1.8.40.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg vala
+
+DESCRIPTION="NetworkManager GUI library"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+# pkcs11 default enabled as it's a small dep often already present by libnma users, and it was default enabled as IUSE=+gcr in nm-applet before
+IUSE="gtk-doc +introspection +pkcs11 vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="
+	>=gui-libs/gtk-4.0:4
+	app-text/iso-codes
+	net-misc/mobile-broadband-provider-info
+	>=dev-libs/glib-2.38:2
+	>=x11-libs/gtk+-3.12:3[introspection?]
+	>=net-misc/networkmanager-1.7[introspection?]
+	pkcs11? ( >=app-crypt/gcr-3.14:= )
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+"
+RDEPEND="${DEPEND}
+	!<gnome-extra/nm-applet-1.16.0" # gschema moved to here before nm-applet-1.16.0
+BDEPEND="
+	dev-libs/libxml2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	vala? ( $(vala_depend)
+		net-misc/networkmanager[vala]
+	)
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dlibnma_gtk4=true
+		$(meson_use pkcs11 gcr)
+		-Dmore_asserts=0
+		-Dgcr_gtk4=false
+		-Diso_codes=true
+		-Dmobile_broadband_provider_info=true
+		-Dld_gc=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}