1 files changed, 42 insertions, 0 deletions
diff --git a/kde-apps/kross-interpreters/kross-interpreters-20.04.0.ebuild b/kde-apps/kross-interpreters/kross-interpreters-20.04.0.ebuild
new file mode 100644
index 000000000000..a57a23cd64d5
--- /dev/null
+++ b/kde-apps/kross-interpreters/kross-interpreters-20.04.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+USE_RUBY="ruby25 ruby26 ruby27"
+KFMIN=5.69.0
+QTMIN=5.12.3
+inherit ecm kde.org python-single-r1 ruby-single
+
+DESCRIPTION="Kross interpreter plugins for programming languages"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="+python ruby"
+
+REQUIRED_USE="|| ( python ruby ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=kde-frameworks/kross-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( ${RUBY_DEPS} )
+"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_python=$(usex python)
+		-DBUILD_ruby=$(usex ruby)
+	)
+
+	ecm_src_configure
+}