2 files changed, 58 insertions, 0 deletions
diff --git a/dev-libs/libofx/Manifest b/dev-libs/libofx/Manifest
index 7c30ee137d3f..7cd2c9d067ae 100644
--- a/dev-libs/libofx/Manifest
+++ b/dev-libs/libofx/Manifest
@@ -1 +1,2 @@
+DIST libofx-0.10.0.tar.gz 225574 BLAKE2B 29ce24ce8f0a333e2d35371cba217223e59e72e1f41051279c15033fecd5f33d7381e9be8403f2e639c007ca6aca1d53cf651e057c9842350772c2296b92c436 SHA512 b7767088701e22a2eba072c365d379987c6e9b2403888550068d6f62f48eaee7935e5355fa6ec97ac7a79bb847c833552250c0bd3065f9274b209585a7884f1d
 DIST libofx-0.9.15.tar.gz 207361 BLAKE2B c84fd4593a9888268c691653dc1b5fff5c38013f12ccc4a8454f9a5026ba190388e5747074aa800266efcfd49a0fdb391a605d5837f664bdcb8fe1dc5c064839 SHA512 6014bf9c457adbe9053a47718064e6246c911c3bf081c690bf761650220208aabe94824aaa38794c1834462894b7948a06b3ff6b517a9a84b9f881ba51aee3a1
diff --git a/dev-libs/libofx/libofx-0.10.0.ebuild b/dev-libs/libofx/libofx-0.10.0.ebuild
new file mode 100644
index 000000000000..c1c87bcc0e4b
--- /dev/null
+++ b/dev-libs/libofx/libofx-0.10.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Library to support the Open Financial eXchange XML format"
+HOMEPAGE="https://github.com/libofx/libofx"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/10"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-util/gengetopt
+	sys-apps/help2man
+	virtual/pkgconfig
+	test? ( app-crypt/gnupg )
+"
+RDEPEND="
+	>=dev-cpp/libxmlpp-2.40.1:2.6
+	>=net-misc/curl-7.9.7
+	virtual/libiconv
+"
+DEPEND="${RDEPEND}
+	>app-text/opensp-1.5
+"
+
+src_prepare() {
+	default
+
+	# Not included in the tarball
+	sed -i -e '/INSTALL/d' Makefile.am || die
+	# Use correct location for docs
+	sed -i -e 's:doc/libofx:doc/${PF}:' Makefile.am doc/Makefile.am || die
+
+	eautoreconf
+	append-cxxflags -std=c++14 # bug #566456
+}
+
+src_compile() {
+	emake -j1
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -type f -delete || die
+
+	if ! use static-libs; then
+		find "${ED}" -name '*.a' -type f -delete || die
+	fi
+}