media-gfx/gnome-photos: bump to 3.22.5; rework grilo-plugins handling, add missing online miners dep

gnome-photos optionally depends on upnp-av and flickr out of grilo-plugins only, and we were
missing flickr. Instead of hard depending on flickr, in addition to upnp-av, move them both
under a USE flag, so those not using flickr or DLNA don't get forced to pull in the whole
dleyna stack or the flickr stuff (though the latter is just oauth).

Similarly for pulling photos, gnome-online-miners are used, but this dependency wasn't specified.
So add it as a RDEPEND and move grilo-plugins as a pure RDEPEND as well. gnome-online-miners
always has facebook/google/media-server support, which gnome-photos uses, but it also optionally
uses flickr online miner, so echo the USE dependency to that as well.

3 files changed, 71 insertions, 0 deletions

diff --git a/media-gfx/gnome-photos/Manifest b/media-gfx/gnome-photos/Manifest
index 1975e77f2d95..a09e282b97e6 100644
--- a/media-gfx/gnome-photos/Manifest
+++ b/media-gfx/gnome-photos/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-photos-3.20.4.tar.xz 929828 SHA256 9ca30753b96368b01d7dca91c130be8ba688ac6d200ff21101992f9171b4ee34 SHA512 179d9e011186dd99dfe9da056c1b5a8ea2adf024fbead90e222ae0f350b78d9b4b7b73a67a21df0c2319fdeb9491e6c0180107768e9ae5ee0fe599bd5e2075ad WHIRLPOOL e3d6e7afd950310c36d85668efdc38bed8f28ab10d761e17b27ca16500369ec1befd56bb4630b344e611945e8c11b1305b48b3f2173a1a63a15eabdc00fb0fba
 DIST gnome-photos-3.22.3.tar.xz 961204 SHA256 5b8cce0f7ff5cb2b863c6d89455b1498b46b71eaebdb8cc2ce1c0fba6e6d2152 SHA512 184211213d8d2749d15cca71fdb1e3274631948f6d9d0a09d0ce940374091c491d094e0fadd7a6cba70b9a8a7c13162c01fc693160bebab17fc192e5a27c254e WHIRLPOOL b60932ca190be304ea70b631212fd47b9bb77570a33e5e216b872bb15ecf47fe8f7969ec78e4014bd10d61ab75fa54cd9a36b9f6effbae1b608e9560d3365d1e
+DIST gnome-photos-3.22.5.tar.xz 961844 SHA256 99a64bc95690c67d24d6db64c0ba1cdc2c2e1acbb3f2fa783fddaafd4a015b64 SHA512 99c3dd08fe35280a231471aaf7436a461b78329a338295c7b0f6edc7210c1bd83954228ff03ce18187dfbef5e627ce31cbb656403edd14531e8927aba2ee7447 WHIRLPOOL 2f242e1d51b078e2816c56cb7f3fed5c1774c98af194fc30103c2379f5d14b7460e462c6b820994640c9b4eb9478c313e578c5094888a5cd67d52da78a010636
diff --git a/media-gfx/gnome-photos/gnome-photos-3.22.5.ebuild b/media-gfx/gnome-photos/gnome-photos-3.22.5.ebuild
new file mode 100644
index 000000000000..94b210aa6736
--- /dev/null
+++ b/media-gfx/gnome-photos/gnome-photos-3.22.5.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="Access, organize and share your photos on GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Photos"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flickr test upnp-av"
+
+COMMON_DEPEND="
+	>=app-misc/tracker-1:=[miner-fs]
+	>=dev-libs/glib-2.44:2
+	gnome-base/gnome-desktop:3=
+	>=dev-libs/libgdata-0.15.2:0=[gnome-online-accounts]
+	media-libs/babl
+	>=media-libs/gegl-0.3.5:0.3[cairo,jpeg2k,raw]
+	media-libs/gexiv2
+	>=media-libs/grilo-0.3.0:0.3=
+	>=media-libs/libpng-1.6:0=
+	>=net-libs/gnome-online-accounts-3.8:=
+	>=net-libs/libgfbgraph-0.2.1:0.2
+	>=x11-libs/cairo-1.14
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.19.1:3
+"
+# gnome-online-miners is also used for google, facebook, DLNA - not only flickr
+# but out of all the grilo-plugins, only upnp-av and flicr get used, which have USE flags here,
+# so don't pull it always, but only if either USE flag is enabled
+RDEPEND="${COMMON_DEPEND}
+	net-misc/gnome-online-miners[flickr?]
+	upnp-av? ( media-plugins/grilo-plugins:0.3[upnp-av] )
+	flickr? ( media-plugins/grilo-plugins:0.3[flickr] )
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	dev-util/desktop-file-utils
+	>=dev-util/intltool-0.50.1
+	virtual/pkgconfig
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	# XXX: how to deal with rdtscp support, x86intrin
+	gnome2_src_configure \
+		$(use_enable test dogtail)
+}
+
+src_test() {
+	virtx emake check
+}
diff --git a/media-gfx/gnome-photos/metadata.xml b/media-gfx/gnome-photos/metadata.xml
index 39980802b1da..97374ee59f59 100644
--- a/media-gfx/gnome-photos/metadata.xml
+++ b/media-gfx/gnome-photos/metadata.xml
@@ -5,4 +5,7 @@
 	<email>gnome@gentoo.org</email>
 	<name>Gentoo GNOME Desktop</name>
 </maintainer>
+<use>
+	<flag name="flickr">Ensure runtime Flickr support</flag>
+</use>
 </pkgmetadata>