dev-ruby/actionmailer: add 6.0.4.4

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-ruby/actionmailer/actionmailer-6.0.4.4.ebuild b/dev-ruby/actionmailer/actionmailer-6.0.4.4.ebuild
new file mode 100644
index 000000000000..5c5d6a444fcc
--- /dev/null
+++ b/dev-ruby/actionmailer/actionmailer-6.0.4.4.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby26 ruby27"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="actionmailer.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="Framework for designing email-service layers"
+HOMEPAGE="https://github.com/rails/rails"
+SRC_URI="https://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RUBY_S="rails-${PV}/${PN}"
+
+ruby_add_rdepend "
+	~dev-ruby/actionpack-${PV}
+	~dev-ruby/actionview-${PV}
+	~dev-ruby/activejob-${PV}
+	>=dev-ruby/mail-2.5.4:* =dev-ruby/mail-2*:*
+	dev-ruby/rails-dom-testing:2"
+
+ruby_add_bdepend "test? (
+	dev-ruby/mocha
+)"
+
+all_ruby_prepare() {
+	# Set test environment to our hand.
+	rm "${S}/../Gemfile" || die "Unable to remove Gemfile"
+	sed -i -e '/\/load_paths/d' test/abstract_unit.rb || die "Unable to remove load paths"
+	sed -i -e '2igem "railties", "~> 6.0.0" ; gem "activejob", "~> 6.0.0"' test/abstract_unit.rb || die
+
+	# Avoid a test failing only on attachment ordering, since this is a
+	# security release.
+	sed -i -e '/adding inline attachments while rendering mail works/askip "gentoo: fails on ordering"' test/base_test.rb || die
+}