dev-python/pypy3-exe: Bump to 7.3.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 168 insertions, 0 deletions

diff --git a/dev-python/pypy3-exe/Manifest b/dev-python/pypy3-exe/Manifest
index ed17644ac383..8a442965ec97 100644
--- a/dev-python/pypy3-exe/Manifest
+++ b/dev-python/pypy3-exe/Manifest
@@ -1,8 +1,10 @@
 DIST pypy3.7-gentoo-patches-7.3.5.tar.xz 8164 BLAKE2B 0f8707fda16c0358c1d3a2a60d83046bc5c6186906e07d0e2441d26da4c5d2e7978aa9013be211daf0a1bfddbb10f96745ba4be84b61903e177f4d906045ed67 SHA512 95d3acb11c811e4342ba3a56e925433614c5affb6a1fc873ecd2f2cfd55459424088b928f46bcb9a6f0e467fb77905af387ad04bad45a37b928fe0ea320ac33e
 DIST pypy3.7-v7.3.5-src.tar.bz2 25350766 BLAKE2B 34d5c83284271b184f71492dbd65b8760cc0fcdec71e41ef48b9561280dd67ef4c37fdd70759d0b95114d127446fc0ea5d04feb99022c1a725233862b2028834 SHA512 253d2efc81d55fb392ab810741e3a633f664e1908b2c26db7a8830c971655cca6be1b8d34581d13aa2d738a4a4c8ba23c2c90333b6e03d4608372e8013ea723b
+DIST pypy3.8-gentoo-patches-7.3.6.tar.xz 4392 BLAKE2B 757581efb1cd0e44279177a4a3d69ba2d34991c702247794cbfd8ee7a31dc6ad70ca41175689fbd31990286a3c60aec9bb5ce189cee1224f20d1f3452fbb958a SHA512 2ee6bc687a50fc1fb9ec5700fdfc4313c5f9b76a8e4da627cc8265e11cdbe8af2c92681207a1c9d869e89e1922c765410dd7790d0a39eadd00a6c2339bc1cfbe
 DIST pypy3.8-gentoo-patches-7.3.6rc1.tar.xz 4660 BLAKE2B 2a1fff331707a29dfb232ce4c2c6d3cada127b4452036172c3aac7579d89b8e0d4ea41300ffcadf0ec04b9cde32044371d55d225a477f2178dddb03642aa569b SHA512 bb781369d4e0dd387659fc474c7a23d8c54ab88477fdd007d3552c95e870a1896a0628dbba876e870956c5a1efeb52efbfd343a08f8a70a4515f41b1dc8ed60d
 DIST pypy3.8-gentoo-patches-7.3.6rc2.tar.xz 4380 BLAKE2B 1ad68c088d4888d3579c0b48789be3a95413ab8f11d971f9f616a1701ceed2b8eba595612e28dbbdbc1732e4f8a7cd08cbbb89cdc413d1a3e9eabbcd78fdde76 SHA512 c2d68610b78ed33aaa67ce5244d289409256f66f2505ac19f0a679c0c10e6024993bbc7d37a59547daac38d321653b8b1a63c55e3f52d1409969f0961842fdd7
 DIST pypy3.8-gentoo-patches-7.3.6rc3.tar.xz 4380 BLAKE2B 03159baf9fb33b65406df47272940cf6adfe2891994787b057d6925edd74063c4f1e4ac115b17d7a41a5d220e9ba27a68f4138792624cc50c2c6aee3a6d385ff SHA512 d88b3f97880735d84746970ef6ac05babde9d88ae6740411a646cec8618816d982a99ccf0628b73690cacc5a4ac9485160242c85756adad75ab7e3ad860b4e42
+DIST pypy3.8-v7.3.6-src.tar.bz2 24377230 BLAKE2B ca5890ded9b3d3bd4ee25911594bafec13b4226dee7f3464ad4386f01011870fac823ddbc1aebf7a813e3ad158baac24df631baf86a7e44ef6efdc7ae2763555 SHA512 2617e444f5ff73bb8ddea58b18849bedcc007feaeb748e9006a3c36401ab26d1c4aaf51eb148654d6bb8221f2e6624c45d3a75124c8912ca59756dfaa14a7068
 DIST pypy3.8-v7.3.6rc1-src.tar.bz2 24320127 BLAKE2B 920738d1d9a346dca8e76602fc5a1502ff6f610897e1f5b841b5207a32f82c52770684ba4ea076209e18b664cb9ba5df555a21f838ae581b436cbff9e2adb506 SHA512 334baf973397f8068137382c29632afd1288b76b57f21047bef59397d2718d8c420ba68acc2f1082501aadf7fbf8ee6a9fa86405c2a54d720a9a02dd7a7371aa
 DIST pypy3.8-v7.3.6rc2-src.tar.bz2 24350986 BLAKE2B fe167b7e1f4f81e1737220bb679874a1e0faa8605b0ec7d10db275c08226e12f8fcff5b958a5a2c42efba5125d88dea150b707441af13bd9b7ef0c9ef36d9c1b SHA512 98715c4053d995a442877f93b32ecb976ffc4160df869d35843718bacfd97d2bbd697f85b5961c420f8130d22e64d740d8d180a4f9ff802250897b4b8c216a6a
 DIST pypy3.8-v7.3.6rc3-src.tar.bz2 24374611 BLAKE2B 5b04bf5fa2f3f2f25a837add74ad716146681e1203ccdb915eed6d1f7f70cd9cb73426f63d310fd76fef2daf6537137d99fa14483886b2cf9946e979243de26f SHA512 872252ff8f090523d79c8d9acec07390587ab38075f35d25f2010ed5ea85537aaa9acb14d049a0a8059757f6c2c1411e9b5e23fec0b1ec2cfcca70e82e6e1c8f
diff --git a/dev-python/pypy3-exe/pypy3-exe-7.3.6.ebuild b/dev-python/pypy3-exe/pypy3-exe-7.3.6.ebuild
new file mode 100644
index 000000000000..c8cc24bbcba0
--- /dev/null
+++ b/dev-python/pypy3-exe/pypy3-exe-7.3.6.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# pypy3 needs to be built using python 2
+PYTHON_COMPAT=( python2_7 )
+inherit check-reqs pax-utils python-any-r1 toolchain-funcs
+
+PYPY_PV=${PV%_p*}
+MY_P=pypy3.8-v${PYPY_PV/_}
+PATCHSET="pypy3.8-gentoo-patches-${PV/_}"
+
+DESCRIPTION="PyPy3 executable (build from source)"
+HOMEPAGE="https://www.pypy.org/"
+SRC_URI="https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz"
+S="${WORKDIR}/${MY_P}-src"
+
+LICENSE="MIT"
+SLOT="${PYPY_PV}"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="bzip2 +jit low-memory ncurses cpu_flags_x86_sse2"
+
+RDEPEND=">=sys-libs/zlib-1.1.3:0=
+	dev-libs/libffi:0=
+	virtual/libintl:0=
+	dev-libs/expat:0=
+	bzip2? ( app-arch/bzip2:0= )
+	ncurses? ( sys-libs/ncurses:0= )
+	!dev-python/pypy3-exe-bin:${PYPY_PV}"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	low-memory? ( dev-python/pypy )
+	!low-memory? (
+		|| (
+			dev-python/pypy
+			dev-lang/python:2.7
+		)
+	)"
+
+check_env() {
+	if use low-memory; then
+		CHECKREQS_MEMORY="1750M"
+		use amd64 && CHECKREQS_MEMORY="3500M"
+	else
+		CHECKREQS_MEMORY="3G"
+		use amd64 && CHECKREQS_MEMORY="6G"
+	fi
+
+	check-reqs_pkg_pretend
+}
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && check_env
+}
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		check_env
+
+		# unset to allow forcing pypy below :)
+		use low-memory && EPYTHON=
+		if [[ ! ${EPYTHON} || ${EPYTHON} == pypy ]] &&
+				{ has_version -b dev-python/pypy ||
+				has_version -b dev-python/pypy-bin; }
+		then
+			einfo "Using PyPy to perform the translation."
+			EPYTHON=pypy
+		else
+			einfo "Using ${EPYTHON:-python2} to perform the translation. Please note that upstream"
+			einfo "recommends using PyPy for that. If you wish to do so, please install"
+			einfo "dev-python/pypy and ensure that EPYTHON variable is unset."
+			python-any-r1_pkg_setup
+		fi
+	fi
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+	default
+}
+
+src_configure() {
+	tc-export CC
+
+	local jit_backend
+	if use jit; then
+		jit_backend='--jit-backend='
+
+		# We only need the explicit sse2 switch for x86.
+		# On other arches we can rely on autodetection which uses
+		# compiler macros. Plus, --jit-backend= doesn't accept all
+		# the modern values...
+
+		if use x86; then
+			if use cpu_flags_x86_sse2; then
+				jit_backend+=x86
+			else
+				jit_backend+=x86-without-sse2
+			fi
+		else
+			jit_backend+=auto
+		fi
+	fi
+
+	local args=(
+		--no-shared
+		$(usex jit -Ojit -O2)
+
+		${jit_backend}
+
+		pypy/goal/targetpypystandalone
+	)
+
+	# Avoid linking against libraries disabled by use flags
+	local opts=(
+		bzip2:bz2
+		ncurses:_minimal_curses
+	)
+
+	local opt
+	for opt in "${opts[@]}"; do
+		local flag=${opt%:*}
+		local mod=${opt#*:}
+
+		args+=(
+			$(usex ${flag} --withmod --withoutmod)-${mod}
+		)
+	done
+
+	local interp=( "${EPYTHON}" )
+	if use low-memory; then
+		interp=( env PYPY_GC_MAX_DELTA=200MB
+			"${EPYTHON}" --jit loop_longevity=300 )
+	fi
+
+	if [[ ${EPYTHON} != pypy ]]; then
+		# reuse bundled pycparser to avoid external dep
+		mkdir -p "${T}"/pymod/cffi || die
+		: > "${T}"/pymod/cffi/__init__.py || die
+		cp -r lib_pypy/cffi/_pycparser "${T}"/pymod/cffi/ || die
+		local -x PYTHONPATH=${T}/pymod:${PYTHONPATH}
+	fi
+
+	# translate into the C sources
+	# we're going to build them ourselves since otherwise pypy does not
+	# free up the unneeded memory before spawning the compiler
+	set -- "${interp[@]}" rpython/bin/rpython --batch --source "${args[@]}"
+	echo -e "\033[1m${@}\033[0m"
+	"${@}" || die "translation failed"
+}
+
+src_compile() {
+	emake -C "${T}"/usession*-0/testing_1
+}
+
+src_install() {
+	cd "${T}"/usession*-0 || die
+	newbin testing_1/pypy3-c pypy3-c-${PYPY_PV}
+	insinto /usr/include/pypy3.8/${PYPY_PV}
+	doins pypy_*.h
+	pax-mark m "${ED}/usr/bin/pypy3-c-${PYPY_PV}"
+}