dev-python/docker-py: Bump to 4.2.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 46 insertions, 0 deletions

diff --git a/dev-python/docker-py/Manifest b/dev-python/docker-py/Manifest
index 4c8d9e63810d..e02b6371f7e8 100644
--- a/dev-python/docker-py/Manifest
+++ b/dev-python/docker-py/Manifest
@@ -1 +1,2 @@
 DIST docker-py-4.2.0.tar.gz 234304 BLAKE2B 385f7fbfaabd4732a2f3bb074094b9f286ee9c6a543432f9a15fc6a78a595f44e4ddebcb3037ff1df54cb4b8d6aec40d8961fb4f62710a0a3245eb886d830c80 SHA512 df5a450355f11d580568ebb0e80abc967df35f2ae10ce83c4ece85e4cf3e97d9cd15e5f14a2d9a43650a844d9402a8d97370f6e5f615c186b12968379e52fa38
+DIST docker-py-4.2.1.tar.gz 234562 BLAKE2B 4b554199f3675340602be27395e0194e827ad81dab48500bca0d4858c699e79ac5108f46eae09c3ac6ae1b580498fd5c78f026ecfd8549b938bb5c6e6cccbd94 SHA512 46ab02d4c247d41efa0ca75d3e13f8aef2d3fe4e6d8624c5a98a728f16c58d0dd8de742be710dc2b2f616dc2cc14a7a8796899e94a4b71a00554baeab105330f
diff --git a/dev-python/docker-py/docker-py-4.2.1.ebuild b/dev-python/docker-py/docker-py-4.2.1.ebuild
new file mode 100644
index 000000000000..a515db65a0c0
--- /dev/null
+++ b/dev-python/docker-py/docker-py-4.2.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="https://github.com/docker/docker-py"
+SRC_URI="https://github.com/docker/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	!~dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/paramiko-2.4.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/recommonmark' \
+	'>=dev-python/sphinx-1.4.6'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# localhost has a better chance of being in /etc/hosts
+	sed -e 's:socket[.]gethostname():"localhost":' \
+		-i tests/unit/api_test.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pytest -vv tests/unit/ || die "tests failed under ${EPYTHON}"
+}