www-client/falkon: 23.03.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 93 insertions, 0 deletions

diff --git a/www-client/falkon/Manifest b/www-client/falkon/Manifest
index cc4ec42b59..0a16c56923 100644
--- a/www-client/falkon/Manifest
+++ b/www-client/falkon/Manifest
@@ -1 +1,2 @@
 DIST falkon-23.03.80.tar.xz 2552208 BLAKE2B 1dbdbe24ab058911a4b088be6918e66fcb2364f4cb07ef04a16f1b80d7274ac67620389302879025b3f2806a15e041706f78dda2f0f004b2fa9fc53abc1d7175 SHA512 b670340d487009034724af6ddfdc4ee9efe05ca63a7b3b5025c34fff305eea580a657f5ff12709efb2ac853523ade2aa11744aa9c4470dd23a4a8675b84f97fb
+DIST falkon-23.03.90.tar.xz 2552200 BLAKE2B f1eee49ff4f412f09ae1d190140e0f82e0499d569b8b10670fd950cf6616f3cba4d971f8862c41b166cd4a5b96f2e8785c30241ede5a82c51c1d9d40eb1b763f SHA512 33783c7b80c87ee98b4fd5eddbea385c8bb153df062ec6fa9143da25d094756f2225d7c69584d5fff3cbff5459e7eedf0ff566061bec6e83bbe2f11e0e7f7c4c
diff --git a/www-client/falkon/falkon-23.03.90.ebuild b/www-client/falkon/falkon-23.03.90.ebuild
new file mode 100644
index 0000000000..142020e6a4
--- /dev/null
+++ b/www-client/falkon/falkon-23.03.90.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.104.0
+QTMIN=5.15.5
+PYTHON_COMPAT=( python3_{9..11} )
+VIRTUALX_REQUIRED="test"
+inherit ecm gear.kde.org python-single-r1
+
+DESCRIPTION="Cross-platform web browser using QtWebEngine"
+HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="dbus kde python +X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test" # bug 653046
+
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5[ssl]
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5[sqlite]
+	>=dev-qt/qtwebchannel-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5=[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	virtual/libintl
+	dbus? ( >=dev-qt/qtdbus-${QTMIN}:5 )
+	kde? (
+		>=kde-frameworks/kcoreaddons-${KFMIN}:5
+		>=kde-frameworks/kcrash-${KFMIN}:5
+		>=kde-frameworks/kio-${KFMIN}:5
+		>=kde-frameworks/kwallet-${KFMIN}:5
+		>=kde-frameworks/purpose-${KFMIN}:5
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep "
+			>=dev-python/pyside2-${QTMIN}[designer,gui,webengine,widgets,\${PYTHON_USEDEP}] \
+			>=dev-python/shiboken2-${QTMIN}[\${PYTHON_USEDEP}]
+		")
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libxcb:=
+		x11-libs/xcb-util
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:5"
+fi
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:5
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+PATCHES=( "${FILESDIR}/${PN}-22.04.3-python3.patch" )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_KEYRING=OFF
+		-DDISABLE_DBUS=$(usex !dbus)
+		$(cmake_use_find_package kde KF5Wallet)
+		$(cmake_use_find_package kde KF5KIO)
+		$(cmake_use_find_package python PySide2)
+		$(cmake_use_find_package python Shiboken2)
+		$(cmake_use_find_package python Python3)
+		-DNO_X11=$(usex !X)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	ecm_src_configure
+}