1 files changed, 73 insertions, 0 deletions
diff --git a/app-antivirus/skyldav/skyldav-0.4_p20141106.ebuild b/app-antivirus/skyldav/skyldav-0.4_p20141106.ebuild
new file mode 100644
index 0000000..eb988d6
--- /dev/null
+++ b/app-antivirus/skyldav/skyldav-0.4_p20141106.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+inherit flag-o-matic linux-info linux-mod autotools-utils
+
+DESCRIPTION="Skyld AV: on-access scanning daemon for ClamAV using fanotify"
+HOMEPAGE="http://xypron.github.io/skyldav/"
+
+## github release tarball
+#MY_PV=${PV/_rc/rc}
+#MY_P="${PN}-${MY_PV}"
+#SRC_URI="https://github.com/xypron/skyldav/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+
+## selfmade tarball
+#MY_PVR=${PVR/_rc/rc}
+#MY_P="${PN}-${MY_PVR}"
+#SRC_URI="http://dev.gentoo.org/~wschlich/src/${CATEGORY}/${PN}/${MY_P}.tar.gz"
+
+## github commit tarball
+MY_GIT_COMMIT="a54c2520d8b3eafa6b68c1c577586a78a0989362"
+MY_P="xypron-${PN}-${MY_GIT_COMMIT:0:7}"
+SRC_URI="https://github.com/xypron/${PN}/tarball/${MY_GIT_COMMIT} -> ${PF}.tar.gz"
+
+S="${WORKDIR}/${MY_P}"
+
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+LICENSE="Apache-2.0"
+IUSE="libnotify"
+
+RDEPEND=">=app-antivirus/clamav-0.97.8
+	sys-apps/util-linux
+	sys-libs/libcap
+	libnotify? (
+		media-libs/libcanberra[gtk]
+		x11-libs/libnotify
+		x11-libs/gtk+:2
+	)"
+DEPEND="${RDEPEND}
+	sys-devel/autoconf-archive"
+
+## autotools-utils.eclass settings
+AUTOTOOLS_AUTORECONF="1"
+AUTOTOOLS_IN_SOURCE_BUILD="1"
+DOCS=( AUTHORS NEWS README )
+PATCHES=(
+	"${FILESDIR}/${PN}-0.2_rc4-more-syslog-messages.patch"
+	"${FILESDIR}/${PN}-0.2_rc4-examples.patch"
+	"${FILESDIR}/${P%%_p*}-conf.patch"
+)
+
+pkg_setup() {
+	linux-info_pkg_setup
+	kernel_is ge 3 8 0 || die "Linux 3.8.0 or newer recommended"
+	CONFIG_CHECK="FANOTIFY FANOTIFY_ACCESS_PERMISSIONS"
+	check_extra_config
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with libnotify notification)
+	)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+	newinitd "${FILESDIR}/${PN}.initd" ${PN}
+	newconfd "${FILESDIR}/${PN}.confd" ${PN}
+}