# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit eutils libtool

DESCRIPTION="Enlightenment DR17 window manager"
HOMEPAGE="http://www.enlightenment.org/"
SRC_URI="http://download.enlightenment.org/rel/apps/${PN}/${P}.tar.bz2"

LICENSE="BSD-2"
KEYWORDS="~amd64 ~x86"
SLOT="0.17/0.18"

E_MODULES_DEFAULT=(
	conf-applications conf-bindings conf-comp conf-dialogs conf-display
	conf-interaction conf-intl conf-menus conf-paths conf-performance
	conf-randr conf-shelves conf-theme conf-window-manipulation
	conf-window-remembers

	appmenu backlight battery bluez4 clock connman contact cpufreq everything
	fileman fileman-opinfo gadman ibar ibox mixer msgbus music-control
	notification pager quickaccess shot start syscon systray tasks teamwork
	temperature tiling winlist wizard xkbswitch
)
E_MODULES=(
	conf-wallpaper2

	access illume2 wl-desktop-shell wl-screenshot
)
IUSE_E_MODULES=(
	"${E_MODULES_DEFAULT[@]/#/+enlightenment_modules_}"
	"${E_MODULES[@]/#/enlightenment_modules_}"
)
IUSE="doc egl nls pam static-libs systemd +udev ukit wayland ${IUSE_E_MODULES[@]}"

RDEPEND="
	>=dev-libs/efl-1.8.1[X,egl?,wayland?]
	>=media-libs/elementary-1.8.0
	virtual/udev
	x11-libs/xcb-util-keysyms
	enlightenment_modules_mixer? ( >=media-libs/alsa-lib-1.0.8 )
	nls? ( sys-devel/gettext )
	pam? ( sys-libs/pam )
	systemd? ( sys-apps/systemd )
	wayland? (
		>=dev-libs/wayland-1.3.0
		>=x11-libs/pixman-0.31.1
		>=x11-libs/libxkbcommon-0.3.1
	)"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

src_prepare() {
	elibtoolize
}

src_configure() {
	local config=(
		--disable-install-sysactions
		--disable-device-hal
		--enable-conf
		--enable-enlightenment-menu
		--enable-device-udev
		--enable-enotify
		--enable-files
		$(use_enable doc)
		$(use_enable egl wayland-egl)
		$(use_enable nls)
		$(use_enable pam)
		$(use_enable static-libs static)
		$(use_enable systemd)
		$(use_enable udev mount-eeze)
		$(use_enable ukit mount-udisks)
		$(use_enable wayland wayland-clients)
	)

	local i
	for i in ${E_MODULES_DEFAULT} ${E_MODULES}; do
		config+=( $(use_enable enlightenment_modules_${i} ${i}) )
	done

	if use wayland; then
		config+=( --enable-enlightenment_modules_wl-desktop-shell )
	fi

	econf "${config[@]}"
}

src_install() {
	default
	prune_libtool_files

	insinto /etc/enlightenment
	newins "${FILESDIR}"/gentoo-sysactions.conf sysactions.conf
}