1 files changed, 64 insertions, 0 deletions
diff --git a/www-apps/pydio/pydio-7.0.4.ebuild b/www-apps/pydio/pydio-7.0.4.ebuild
new file mode 100644
index 0000000..780b20f
--- /dev/null
+++ b/www-apps/pydio/pydio-7.0.4.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit webapp
+
+DESCRIPTION="File sharing platform similar to dropbox"
+HOMEPAGE="https://pydio.com/"
+SRC_URI="https://download.pydio.com/pub/core/archives/${PN}-core-${PV}.tar.gz -> ${P}.tar.gz"
+RESTRICTION="mirror"
+
+LICENSE="AGPL-3"
+KEYWORDS="~amd64 ~x86"
+IUSE="+webdav"
+
+DEPEND="webdav? ( dev-php/PEAR-HTTP_WebDAV_Client )"
+RDEPEND="${DEPEND}
+	virtual/httpd-php
+"
+
+S="${WORKDIR}/${PN}-core-${PV}"
+
+src_prepare() {
+	default
+
+	# Fix compatibility with Apache 2.4
+	while read htaccess ; do
+		LC_ALL=C sed -i \
+			-e 's/^[Dd]eny from all/Require all denied/' \
+			-e 's/^[Aa]llow from all/Require all granted/' \
+			-e '/^Order /d' \
+			"${htaccess}"
+	done < <(find "${S}" -name ".htaccess")
+}
+
+src_install() {
+	webapp_src_preinst
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r "${S}"/*
+
+	insinto "${MY_HTDOCSDIR}"/upgrade-scripts
+	doins "${FILESDIR}"/*.php
+
+	webapp_serverowned -R "${MY_HTDOCSDIR}"/data
+
+	webapp_configfile "${MY_HTDOCSDIR}/base.conf.php"
+	webapp_configfile "${MY_HTDOCSDIR}/conf/bootstrap_"{conf,context,repositories}".php"
+	webapp_configfile "${MY_HTDOCSDIR}/conf/mime.types"
+	webapp_configfile "${MY_HTDOCSDIR}/conf/extensions.conf.php"
+
+	# FIXME: does not fit eclass design
+	#webapp_sqlscript mysql "${MY_HTDOCSDIR}"/plugins/*/create.mysql
+	#webapp_sqlscript postgres "${MY_HTDOCSDIR}"/plugins/*/create.pgsql
+
+	webapp_sqlscript mysql "${FILESDIR}"/7.0.1.mysql 6.4
+	webapp_sqlscript mysql "${FILESDIR}"/7.0.2.mysql 7.0.1
+	webapp_sqlscript postgres "${FILESDIR}"/7.0.1.pgsql 6.4
+
+	webapp_postinst_txt en "${FILESDIR}"/postinst.en.txt
+
+	webapp_src_install
+}