From 76b4c8952e3464b0ee5844e1eda50afdd9f0f4d9 Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Thu, 25 Nov 2010 13:42:21 +0000
Subject: Version bump.

(Portage version: 2.1.9.24/cvs/Linux i686)
---
 net-ftp/lftp/lftp-4.1.1.ebuild | 67 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 net-ftp/lftp/lftp-4.1.1.ebuild

(limited to 'net-ftp/lftp/lftp-4.1.1.ebuild')

diff --git a/net-ftp/lftp/lftp-4.1.1.ebuild b/net-ftp/lftp/lftp-4.1.1.ebuild
new file mode 100644
index 000000000000..74356fc59fd7
--- /dev/null
+++ b/net-ftp/lftp/lftp-4.1.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/lftp-4.1.1.ebuild,v 1.1 2010/11/25 13:42:21 jer Exp $
+
+EAPI="2"
+
+inherit autotools eutils
+
+DESCRIPTION="A sophisticated ftp/sftp/http/https/torrent client and file transfer program"
+HOMEPAGE="http://lftp.yar.ru/"
+SRC_URI="http://ftp.yars.free.net/pub/source/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="ssl gnutls socks5 nls"
+
+RDEPEND="
+	>=sys-libs/ncurses-5.1
+	socks5? (
+		>=net-proxy/dante-1.1.12
+		virtual/pam )
+	ssl? (
+		gnutls? ( >=net-libs/gnutls-1.2.3 )
+		!gnutls? ( >=dev-libs/openssl-0.9.6 )
+	)
+	>=sys-libs/readline-5.1
+"
+
+DEPEND="
+	${RDEPEND}
+	nls? ( sys-devel/gettext )
+	dev-lang/perl
+	=sys-devel/libtool-2*
+"
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-4.0.2.91-lafile.patch"
+	epatch "${FILESDIR}/${PN}-4.0.3-autoconf-2.64.patch"
+	eautoreconf
+}
+
+src_configure() {
+	local myconf="$(use_enable nls) --enable-packager-mode"
+
+	if use ssl && use gnutls ; then
+		myconf="${myconf} --without-openssl"
+	elif use ssl && ! use gnutls ; then
+		myconf="${myconf} --without-gnutls --with-openssl=/usr"
+	else
+		myconf="${myconf} --without-gnutls --without-openssl"
+	fi
+
+	use socks5 && myconf="${myconf} --with-socksdante=/usr" \
+		|| myconf="${myconf} --without-socksdante"
+
+	econf \
+		--sysconfdir=/etc/lftp \
+		--with-modules \
+		${myconf} || die "econf failed"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+
+	dodoc BUGS ChangeLog FAQ FEATURES MIRRORS \
+			NEWS README* THANKS TODO
+}
-- 
cgit v1.2.3-65-gdbad